media-plugins/gst-plugins-libnice/gst-plugins-libnice-0.1.3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-plugins/gst-plugins-libnice/gst-plugins-libnice-0.1.3.ebuild,v 1.1 2012/12/08 00:05:50 tetromino Exp $

EAPI="5"

inherit eutils toolchain-funcs

DESCRIPTION="GStreamer plugin for ICE (RFC 5245) support"
HOMEPAGE="http://nice.freedesktop.org/wiki/"
MY_P=libnice-${PV}
SRC_URI="http://nice.freedesktop.org/releases/${MY_P}.tar.gz"

LICENSE="|| ( MPL-1.1 LGPL-2.1 )"
SLOT="0.10"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
IUSE=""

# ${PN} was part of net-libs/libnice before 0.1.3-r1
RDEPEND="~net-libs/libnice-${PV}
	>=media-libs/gstreamer-0.10.10:0.10
	>=media-libs/gst-plugins-base-0.10.10:0.10
	>net-libs/libnice-0.1.3"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

S="${WORKDIR}/${MY_P}/gst"

src_prepare() {
	local pkgconfig=$(tc-getPKG_CONFIG)
	local libs=$("${pkgconfig}" --libs-only-l nice)
	sed -e 's:$(top_builddir)/nice/libnice.la:'"${libs}:" \
		-i Makefile.{am,in} || die "sed failed"
}

src_configure() {
	cd "${WORKDIR}/${MY_P}" || die
	# gupnp is not used in the gst plugin
	econf \
		--disable-static \
		--with-gstreamer-0.10 \
		--without-gstreamer \
		--disable-gupnp
}

src_install() {
	default
	prune_libtool_files --modules
}