media-plugins/kipi-plugins/kipi-plugins-1.1.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-plugins/kipi-plugins/kipi-plugins-1.1.0.ebuild,v 1.2 2010/02/04 21:26:51 ssuominen Exp $

EAPI=2
OPENGL_REQUIRED=optional

KDE_LINGUAS="ar ast be ca ca@valencia cs da de el en_GB eo es et fi fr ga gl hi hne hr is
it ja km lt lv ms nb nds nl nn oc pa pl pt pt_BR ro ru se sk sv th tr uk zh_CN
zh_TW"

inherit kde4-base

DESCRIPTION="KDE Image Plugin Interface"
HOMEPAGE="http://www.kipi-plugins.org/"
SRC_URI="mirror://sourceforge/kipi/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="4"
KEYWORDS="~amd64 ~x86"
IUSE="cdr calendar crypt debug +imagemagick ipod mjpeg redeyes scanner"

DEPEND=">=dev-libs/expat-2.0.1
	>=dev-libs/libxml2-2.7
	dev-libs/libxslt
	>=kde-base/libkdcraw-${KDE_MINIMAL}
	>=kde-base/libkexiv2-${KDE_MINIMAL}
	>=kde-base/libkipi-${KDE_MINIMAL}
	media-libs/jpeg:0
	>=media-libs/libpng-1.2
	media-libs/tiff
	calendar? ( >=kde-base/kdepimlibs-${KDE_MINIMAL} )
	ipod? ( x11-libs/gtk+:2
		>=media-libs/libgpod-0.7 )
	opengl? ( virtual/opengl )
	redeyes? ( media-libs/opencv )
	scanner? ( media-gfx/sane-backends
		>=kde-base/libksane-${KDE_MINIMAL} )
	crypt? ( app-crypt/qca:2 )"
RDEPEND="${DEPEND}
	cdr? ( app-cdr/k3b )
	imagemagick? ( media-gfx/imagemagick )
	mjpeg? ( media-video/mjpegtools )"

DOCS="AUTHORS ChangeLog HACKING NEWS README TODO"

src_configure() {
	mycmakeargs+=( $(cmake-utils_use_with ipod GLIB2)
		$(cmake-utils_use_with ipod GObject)
		$(cmake-utils_use_with ipod Gdk)
		$(cmake-utils_use_with ipod Gpod)
		$(cmake-utils_use_with scanner KSane)
		$(cmake-utils_use_with calendar KdepimLibs)
		$(cmake-utils_use_with redeyes OpenCV)
		$(cmake-utils_use_with opengl OpenGL)
		$(cmake-utils_use_with crypt QCA2) )

	kde4-base_src_configure
}