blob: df9a6d5a372dc4c7491632065740ce316f1e1d9b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
|
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/murmur/murmur-1.2.0_pre20090911.ebuild,v 1.1 2009/09/13 12:22:30 tgurr Exp $
EAPI="2"
inherit eutils qt4
GIT_REV="402695"
MY_PN="${PN/murmur}mumble"
MY_P="mumble-${PV/_pre20090911}~200909111826-${GIT_REV}"
DESCRIPTION="Mumble is an open source, low-latency, high quality voice chat software."
HOMEPAGE="http://mumble.sourceforge.net/"
SRC_URI="http://mumble.info/snapshot/${MY_P}.tar.gz -> ${MY_PN}-${PV}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+dbus debug +ice pch zeroconf"
RDEPEND="dev-libs/openssl
>=dev-libs/protobuf-2.2.0
>=sys-libs/libcap-2.15
x11-libs/qt-core:4[ssl]
|| ( x11-libs/qt-sql:4[sqlite] x11-libs/qt-sql:4[mysql] )
x11-libs/qt-xmlpatterns:4
dbus? ( x11-libs/qt-dbus:4 )
ice? ( dev-cpp/Ice dev-libs/boost )
zeroconf? ( || ( net-dns/avahi[mdnsresponder-compat] net-misc/mDNSResponder ) )"
DEPEND="${RDEPEND}
dev-util/pkgconfig"
S="${WORKDIR}/${MY_P}"
pkg_setup() {
enewgroup murmur
enewuser murmur -1 -1 /var/lib/murmur murmur
}
src_prepare() {
sed -i \
-e 's:mumble-server:murmur:g' \
"${S}"/scripts/murmur.conf \
"${S}"/scripts/murmur.ini.system \
|| die "sed failed."
}
src_configure() {
local conf_add
use dbus || conf_add="${conf_add} no-dbus"
use debug && conf_add="${conf_add} symbols debug" || conf_add="${conf_add} release"
use ice || conf_add="${conf_add} no-ice"
use pch || conf_add="${conf_add} no-pch"
use zeroconf || conf_add="${conf_add} no-bonjour"
eqmake4 main.pro -recursive \
CONFIG+="${conf_add} \
no-client" \
|| die "eqmake4 failed."
}
src_install() {
dodoc README CHANGES || die "Installing docs failed."
docinto scripts
dodoc scripts/*.php scripts/*.pl || die "Installing docs failed."
local dir
if use debug; then
dir=debug
else
dir=release
fi
dobin "${dir}"/murmurd || die "Installing murmurd binary failed."
insinto /etc/murmur/
newins scripts/murmur.ini.system murmur.ini || die "Installing murmur.ini configuration file failed."
insinto /etc/logrotate.d/
newins "${FILESDIR}"/murmur.logrotate murmur || die "Installing murmur logrotate file failed."
insinto /etc/dbus-1/system.d/
doins scripts/murmur.conf || die "Installing murmur.conf dbus configuration file failed."
newinitd "${FILESDIR}"/murmur.initd murmur || die "Installing murmur init.d file failed."
newconfd "${FILESDIR}"/murmur.confd murmur || die "Installing murmur conf.d file failed."
keepdir /var/lib/murmur /var/run/murmur /var/log/murmur
fowners -R murmur /var/lib/murmur /var/run/murmur /var/log/murmur || die "fowners failed."
fperms 750 /var/lib/murmur /var/run/murmur /var/log/murmur || die "fperms failed."
doman man/murmurd.1 || die "Installing murmur manpage failed."
}
pkg_postinst() {
echo
elog "Useful scripts are located in /usr/share/doc/${PF}/scripts."
elog "Please execute:"
elog "murmurd -ini /etc/murmur/murmur.ini -supw <pw>"
elog "chown murmur:murmur /var/lib/murmur/murmur.sqlite"
elog "to set the build-in 'SuperUser' password before starting murmur."
elog "Please restart dbus before starting murmur, or else dbus"
elog "registration will fail."
echo
}
|
GitWeb