net-misc/quickshare/quickshare-1.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/quickshare/quickshare-1.0.ebuild,v 1.2 2012/05/05 03:20:43 jdhore Exp $

EAPI=4
inherit eutils toolchain-funcs

DESCRIPTION="A simple HTTP server with a GUI which allows for easy sharing of files"
HOMEPAGE="http://houbysoft.com/qs/"
SRC_URI="http://houbysoft.com/download/${P}-src.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND="net-libs/libmicrohttpd
	x11-libs/gtk+:2"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

S=${WORKDIR}/${P}-src

src_prepare() {
	sed -i \
		-e 's:gcc ${LOPT}:$(CC) $(LDFLAGS):' \
		-e 's:-o $@:-o $@ ${LOPT}:' \
		-e 's:gcc:$(CC):' \
		Makefile || die
}

src_compile() {
	tc-export CC
	emake COPT="${CFLAGS}"
}

src_install() {
	dobin qs
	dodoc README
	insinto /usr/share/quickshare
	doins {on,off}.png
	make_desktop_entry qs QuickShare
}