blob: 2f4d0f4ad29d98068532f3fa2b4a9521196d15ec (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
|
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-physics/cernlib/cernlib-2006-r4.ebuild,v 1.6 2013/02/20 16:48:39 jlec Exp $
EAPI=4
inherit eutils fortran-2 multilib toolchain-funcs
DEB_PN=cernlib
DEB_PV=20061220+dfsg3
DEB_PR=1
DEB_P=${DEB_PN}_${DEB_PV}
DESCRIPTION="CERN program library for High Energy Physics"
HOMEPAGE="http://wwwasd.web.cern.ch/wwwasd/cernlib"
SRC_URI="
mirror://debian/pool/main/${DEB_PN:0:1}/${DEB_PN}/${DEB_P}.orig.tar.gz
mirror://debian/pool/main/${DEB_PN:0:1}/${DEB_PN}/${DEB_P}-${DEB_PR}.debian.tar.gz"
SLOT="0"
LICENSE="GPL-2 LGPL-2 BSD"
KEYWORDS="~amd64 ~hppa ~sparc ~x86"
IUSE=""
RDEPEND="
x11-libs/motif:0
virtual/lapack
dev-lang/cfortran"
DEPEND="${RDEPEND}
x11-misc/imake
x11-misc/makedepend
virtual/pkgconfig"
S="${WORKDIR}/${DEB_PN}-${DEB_PV}"
src_prepare() {
mv ../debian .
epatch "${FILESDIR}"/${P}-nogfortran.patch
# set some default paths
sed -i \
-e "s:/usr/local:${EPREFIX}/usr:g" \
-e "s:prefix)/lib:prefix)/$(get_libdir):" \
-e "s:\$(prefix)/etc:${EPREFIX}/etc:" \
-e 's:$(prefix)/man:$(prefix)/share/man:' \
debian/add-ons/cernlib.mk || die "sed failed"
# use system blas and lapack set by gentoo framework
sed -i \
-e "s:\$DEPS -lm:$($(tc-getPKG_CONFIG) --libs blas):" \
-e "s:\$DEPS -llapack -lm:$($(tc-getPKG_CONFIG) --libs lapack):" \
-e 's:`depend $d $a blas`::' \
-e 's:X11R6:X11:g' \
debian/add-ons/bin/cernlib.in || die "sed failed"
cp debian/add-ons/Makefile .
export DEB_BUILD_OPTIONS="$(tc-getFC) nostrip nocheck"
einfo "Applying Debian patches"
emake -j1 patch
epatch "${FILESDIR}"/${P}-fgets.patch
# since we depend on cfortran, do not use the one from cernlib
rm -f src/include/cfortran/cfortran.h
# respect users flags
sed -i \
-e 's/-O3/-O2/g' \
-e "s/-O2/${CFLAGS}/g" \
-e "s|\(CcCmd[[:space:]]*\)gcc|\1$(tc-getCC)|g" \
-e "s|\(CplusplusCmd[[:space:]]*\)g++|\1$(tc-getCXX)|g" \
-e "s|\(FortranCmd[[:space:]]*\)gfortran|\1$(tc-getFC)|g" \
src/config/linux.cf \
|| die "sed linux.cf failed"
sed -i \
-e 's/\$(FCLINK)/\$(FCLINK) $(LDFLAGS)/' \
-e 's/\$(CCLINK)/\$(CCLINK) $(LDFLAGS)/' \
src/config/{biglib,fortran,Imake}.rules \
src/patchy/Imakefile \
|| die "sed for ldflags propagation failed"
# add missing headers for implicit
sed -i \
-e '0,/^#include/i#include <stdlib.h>' \
src/kernlib/kerngen/ccgen*/*.c || die
}
src_compile() {
# parallel make breaks and complex patched imake system, hard to debug
emake -j1 cernlib-indep cernlib-arch
}
src_test() {
LD_LIBRARY_PATH="${S}"/shlib emake -j1 cernlib-test
}
src_install() {
emake DESTDIR="${D}" install
cd debian
dodoc changelog README.* deadpool.txt NEWS copyright
newdoc add-ons/README README.add-ons
}
|
GitWeb