sci-physics/espresso++/espresso++-1.6.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-physics/espresso++/espresso++-1.6.0.ebuild,v 1.2 2014/02/16 19:05:53 ottxor Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7} )

inherit cmake-utils multilib python-single-r1

DESCRIPTION="extensible, flexible, fast and parallel simulation software for soft matter research"
HOMEPAGE="https://www.espresso-pp.de"

if [[ ${PV} = 9999 ]]; then
	EHG_REPO_URI="https://hg.berlios.de/repos/espressopp"
	EHG_REVISION="default"
	inherit mercurial
else
	SRC_URI="https://espressopp.mpip-mainz.mpg.de/Download/${PN//+/p}-${PV}.tgz"
	S="${WORKDIR}/${PN//+/p}-${PV}"
	KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-macos"
	PATCHES=( "${FILESDIR}/${P}-multilib.patch" )
fi

CMAKE_REMOVE_MODULES_LIST="FindBoost FindMPI"

EHP_OPTS="--config hostfingerprints.hg.berlios.de=f4:79:d2:17:f8:0c:9b:c2:6e:65:60:2a:49:0e:09:79:85:6d:4b:e3"
EHG_CLONE_CMD="hg clone ${EHG_QUIET_CMD_OPT} ${EHP_OPTS} --pull --noupdate"
EHG_PULL_CMD="hg pull ${EHG_QUIET_CMD_OPT} ${EHP_OPTS}"
LICENSE="GPL-3 !system-boost? ( Boost-1.0 )"
SLOT="0"
IUSE="-system-boost"

REQUIRED_USE="${PYTHON_REQUIRED_USE}"

RDEPEND="${PYTHON_DEPS}
	virtual/mpi
	system-boost? ( dev-libs/boost[python,mpi,${PYTHON_USEDEP}] )"
DEPEND="${RDEPEND}"

DOCS=( AUTHORS NEWS README )

src_configure() {
	mycmakeargs=( $(cmake-utils_use system-boost EXTERNAL_BOOST) -DLIB="$(get_libdir)" )
	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	rm "${ED}/usr/bin/ESPRC" || die
	rmdir "${ED}/usr/bin" || die
}