sci-visualization/fityk/fityk-0.8.7.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-visualization/fityk/fityk-0.8.7.ebuild,v 1.2 2009/06/25 03:16:57 bicatali Exp $

EAPI="2"
WX_GTK_VER="2.8"

inherit eutils autotools wxwidgets

DESCRIPTION="General-purpose nonlinear curve fitting and data analysis"
HOMEPAGE="http://www.unipress.waw.pl/fityk/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"

SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc examples gnuplot readline wxwidgets"

DEPEND=">=sci-libs/xylib-0.4
	readline? ( sys-libs/readline )
	wxwidgets? ( x11-libs/wxGTK:2.8 )
	dev-libs/boost"

RDEPEND="${DEPEND}
	gnuplot? ( sci-visualization/gnuplot )"

src_prepare() {
	# avoid building xylib when 3rdparty is disabled
	epatch "${FILESDIR}"/${P}-3rdparty.patch
	# <libtool-2 compatibility (bug #275290)
	rm -f "${S}"/libtool "${S}"/config/lt* "${S}"/config/libtool.m4
	eautoreconf

	has_version ">=dev-libs/boost-1.37" &&
	sed -i 's:impl/directives.i:directives.h:' "${S}/src/optional_suffix.h"
}

src_configure() {
	econf  \
		--disable-3rdparty \
		$(use_enable wxwidgets GUI) \
		$(use_with doc) \
		$(use_with readline)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc NEWS README TODO || die
	rm -f samples/Makefile*
	insinto /usr/share/doc/${PF}
	use examples && doins -r samples
}