sys-apps/pciutils/pciutils-2.2.0-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/pciutils/pciutils-2.2.0-r1.ebuild,v 1.15 2006/06/21 20:52:24 vapier Exp $

inherit eutils flag-o-matic toolchain-funcs

STAMP=20051015
DESCRIPTION="Various utilities dealing with the PCI bus"
HOMEPAGE="http://atrey.karlin.mff.cuni.cz/~mj/pciutils.html"
SRC_URI="ftp://atrey.karlin.mff.cuni.cz/pub/linux/pci/${P}.tar.gz
	mirror://gentoo/pci.ids-${STAMP}.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="alpha amd64 arm hppa ia64 m68k mips ppc ppc64 s390 sh sparc x86 ~x86-fbsd"
IUSE=""

DEPEND=""

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}"/pcimodules-${P}.patch
	epatch "${FILESDIR}"/${P}-shared-lib.patch

	# Set Gentoo paths
	# and do not strip (breaks cross-compile), portage handles stripping
	sed -i \
		-e '/^PREFIX=/s:=.*:=/usr:' \
		-e '/^IDSDIR=/s:=.*:=$(PREFIX)/share/misc:' \
		-e '/INSTALL.* -s lspci /s: -s lspci : lspci :' \
		Makefile || die

	# Make sure we respect $AR / $RANLIB
	sed -i \
		-e '/ar rcs/s:ar:$(AR):' \
		-e 's:ranlib:$(RANLIB):' \
		lib/Makefile \
		|| die "sed lib/Makefile failed"

	sed -i 's:wget -O:wget --connect-timeout=60 -O:' update-pciids.sh
	ebegin "Updating pci.ids from the web"
	if ! ./update-pciids.sh &> /dev/null ; then
		# if we cant update, use a cached version
		mv "${WORKDIR}"/pci.ids-${STAMP} "${S}"/pci.ids
	fi
	eend 0
}

src_compile() {
	tc-export AR CC RANLIB
	emake OPT="${CFLAGS}" || die "emake failed"
}

src_install() {
	dodir /usr/share/man
	make install PREFIX="${D}"/usr || die

	dolib lib/libpci.* || die "libpci failed"
	insinto /usr/include/pci
	doins lib/{config,header,pci,types}.h || die "headers failed"
}