sys-fs/reiser4progs/reiser4progs-1.0.4.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/reiser4progs/reiser4progs-1.0.4.ebuild,v 1.7 2005/06/27 07:34:26 corsair Exp $

inherit eutils

DESCRIPTION="reiser4progs: mkfs, fsck, etc..."
HOMEPAGE="http://www.namesys.com/v4/v4.html"
SRC_URI="ftp://ftp.namesys.com/pub/reiser4progs/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ppc ppc64 -sparc x86"
IUSE="static debug readline"

DEPEND=">=sys-libs/libaal-${PV}
	readline? ( sys-libs/readline )"

src_unpack() {
	unpack ${A}
	cd "${S}"
	# bundled libtool sucks, so rebuild autotools #74817
	aclocal && libtoolize -c -f && autoconf && automake || die "autotools failed"
	epatch "${FILESDIR}"/${P}-gcc4.patch
	epatch "${FILESDIR}"/${P}.pset.patch
	cat <<-EOF > run-ldconfig
	#!/bin/sh
	true
	EOF
}

src_compile() {
	econf \
		$(use_enable static full-static) \
		$(use_enable static mkfs-static) \
		$(use_enable static fsck-static) \
		$(use_enable static debugfs-static) \
		$(use_enable static measurefs-static) \
		$(use_enable static cpfs-static) \
		$(use_enable static resizefs-static) \
		$(use_enable debug) \
		$(use_with readline) \
		--enable-libminimal \
		--sbindir=/sbin \
		--libdir=/$(get_libdir) \
		|| die "configure failed"
	emake || die "make failed"
}

src_install() {
	make DESTDIR="${D}" install || die
	dodoc AUTHORS BUGS CREDITS ChangeLog NEWS README THANKS TODO
	#resizefs binary doesnt exist in this release
	rm -f "${D}"/usr/share/man/man8/resizefs*

	# move stupid .a out of root
	dodir /usr/$(get_libdir)
	local l=""
	for l in libreiser4-minimal libreiser4 librepair ; do
		mv "${D}"/$(get_libdir)/${l}.{a,la} "${D}"/usr/$(get_libdir)/
		dosym ../usr/lib/${l}.a /lib/${l}.a
		gen_usr_ldscript ${l}.so
	done
}