x11-misc/zim/zim-0.27.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/zim/zim-0.27.ebuild,v 1.3 2009/06/03 01:50:23 ssuominen Exp $

inherit eutils fdo-mime perl-module

MY_P=${P/z/Z}

DESCRIPTION="A desktop wiki"
HOMEPAGE="http://zim-wiki.org/"
SRC_URI="http://www.zim-wiki.org/downloads/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="latex screenshot spell"

COMMON_DEPEND=">=dev-lang/perl-5.8
	>=x11-libs/gtk+-2.10
	virtual/perl-Storable
	virtual/perl-File-Spec
	>=dev-perl/File-BaseDir-0.03
	>=dev-perl/File-MimeInfo-0.12
	>=dev-perl/File-DesktopEntry-0.03
	>=dev-perl/gtk2-perl-1.040
	x11-misc/xdg-utils"
RDEPEND="${COMMON_DEPEND}
	latex? ( virtual/latex-base app-text/dvipng )
	screenshot? ( media-gfx/scrot )
	spell? ( dev-perl/gtk2-spell )"
DEPEND="${COMMON_DEPEND}
	virtual/perl-Module-Build"

S=${WORKDIR}/${MY_P}

PATCHES=( "${FILESDIR}/${PN}-0.27-disable-updates.patch" )

src_install() {
	doicon share/pixmaps/zim.png
	perl-module_src_install
}

pkg_postinst() {
	perl-module_pkg_postinst
	fdo-mime_desktop_database_update
	xdg-icon-resource install --context mimetypes --size 64 \
		"${ROOT}/usr/share/pixmaps/zim.png" \
		application-x-zim-notebook || die "xdg-icon-resource install failed"
}

pkg_postrm() {
	perl-module_pkg_postrm
	fdo-mime_desktop_database_update
	xdg-icon-resource uninstall --context mimetypes --size 64 \
		application-x-zim-notebook || die "xdg-icon-resource uninstall failed"

}