1 files changed, 0 insertions, 120 deletions
diff --git a/dev-libs/gmp/gmp-5.1.3-r99.ebuild b/dev-libs/gmp/gmp-5.1.3-r99.ebuild
deleted file mode 100644
index 5620a887..00000000
--- a/dev-libs/gmp/gmp-5.1.3-r99.ebuild
+++ /dev/null
@@ -1,120 +0,0 @@
-# Copyright 1999-2014 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/gmp/gmp-5.1.3-r1.ebuild,v 1.19 2014/05/14 14:41:58 ago Exp $
-
-EAPI="4"
-
-inherit flag-o-matic eutils libtool toolchain-funcs multilib-minimal
-
-MY_PV=${PV/_p*}
-MY_P=${PN}-${MY_PV}
-PLEVEL=${PV/*p}
-DESCRIPTION="Library for arithmetic on arbitrary precision integers, rational numbers, and floating-point numbers"
-HOMEPAGE="http://gmplib.org/"
-SRC_URI="mirror://gnu/${PN}/${MY_P}.tar.xz
-	ftp://ftp.gmplib.org/pub/${MY_P}/${MY_P}.tar.xz
-	doc? ( http://gmplib.org/${PN}-man-${MY_PV}.pdf )"
-
-LICENSE="LGPL-3"
-SLOT="0"
-KEYWORDS="ppc"
-IUSE="doc cxx pgo static-libs"
-
-DEPEND="sys-devel/m4
-	app-arch/xz-utils"
-RDEPEND="abi_x86_32? (
-	!<=app-emulation/emul-linux-x86-baselibs-20131008-r1
-	!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
-)"
-
-S=${WORKDIR}/${MY_P}
-
-DOCS=( AUTHORS ChangeLog NEWS README doc/configuration doc/isa_abi_headache )
-HTML_DOCS=( doc )
-MULTILIB_WRAPPED_HEADERS=( /usr/include/gmp.h )
-
-src_prepare() {
-	[[ -d ${FILESDIR}/${PV} ]] && EPATCH_SUFFIX="diff" EPATCH_FORCE="yes" epatch "${FILESDIR}"/${PV}
-	epatch "${FILESDIR}"/${PN}-4.1.4-noexecstack.patch
-
-	epatch "${FILESDIR}"/${PN}-5.1.3-secure-plt.patch
-
-	# note: we cannot run autotools here as gcc depends on this package
-	elibtoolize
-
-	# GMP uses the "ABI" env var during configure as does Gentoo (econf).
-	# So, to avoid patching the source constantly, wrap things up.
-	mv configure configure.wrapped || die
-	cat <<-\EOF > configure
-	#!/bin/sh
-	exec env ABI="$GMPABI" "$0.wrapped" "$@"
-	EOF
-	chmod a+rx configure
-}
-
-multilib_src_configure() {
-	# Because of our 32-bit userland, 1.0 is the only HPPA ABI that works
-	# http://gmplib.org/manual/ABI-and-ISA.html#ABI-and-ISA (bug #344613)
-	if [[ ${CHOST} == hppa2.0-* ]] ; then
-		export GMPABI="1.0"
-	fi
-
-	# ABI mappings (needs all architectures supported)
-	case ${ABI} in
-		32|x86)       GMPABI=32;;
-		64|amd64|n64) GMPABI=64;;
-		[onx]32)      GMPABI=${ABI};;
-	esac
-	export GMPABI
-
-	tc-export CC
-	ECONF_SOURCE="${S}" econf \
-		--localstatedir=/var/state/gmp \
-		--enable-shared \
-		$(use_enable cxx) \
-		$(use_enable static-libs static)
-}
-
-multilib_src_compile() {
-	emake
-
-	if use pgo ; then
-		emake -j1 -C tune tuneup
-		ebegin "Trying to generate tuned data"
-		./tune/tuneup | tee gmp.mparam.h.new
-		if eend $(( 0 + ${PIPESTATUS[*]/#/+} )) ; then
-			mv gmp.mparam.h.new gmp-mparam.h || die
-			emake clean
-			emake
-		fi
-	fi
-}
-
-multilib_src_test() {
-	emake check
-}
-
-multilib_src_install() {
-	emake DESTDIR="${D}" install
-
-	# should be a standalone lib
-	rm -f "${D}"/usr/$(get_libdir)/libgmp.la
-	# this requires libgmp
-	local la="${D}/usr/$(get_libdir)/libgmpxx.la"
-	use static-libs \
-		&& sed -i 's:/[^ ]*/libgmp.la:-lgmp:' "${la}" \
-		|| rm -f "${la}"
-}
-
-multilib_src_install_all() {
-	einstalldocs
-	use doc && cp "${DISTDIR}"/gmp-man-${MY_PV}.pdf "${D}"/usr/share/doc/${PF}/
-}
-
-pkg_preinst() {
-	preserve_old_lib /usr/$(get_libdir)/libgmp.so.3
-}
-
-pkg_postinst() {
-	preserve_old_lib_notify /usr/$(get_libdir)/libgmp.so.3
-}