dev-cpp/blitz: 1.0.3_pre fix boost, doxygen dependencies

The blitz-1.0.2_p20200524 provides libblitz.so.1.0.3 therefore
the new ebuild is renamed to *-1.0.3_pre20200524 instead of revision bump
while both use the same git-commit-sha-tarball.

Blitz++ optionally depends on dev-libs/boost[static-libs]
to allow build with Boost::serialization support
(note: cmake option is realy with typo).
USE="boost" is used to handle this option.

Add USE="doc" app-doc/doxygen build dependency to build dev docs.

Add python build time dependency.

The testsuite, benchmark, examples targets now is only conditionally build
in src_compile() and tests are ran in implicit src_test() phase.

Update live ebuild.

Signed-off-by: band-a-prend <torokhov-s-a@yandex.ru>
Signed-off-by: Aisha Tammy <gentoo@aisha.cc>

4 files changed, 90 insertions, 19 deletions

diff --git a/dev-cpp/blitz/Manifest b/dev-cpp/blitz/Manifest
index a4e6563b2..ae8c40b70 100644
--- a/dev-cpp/blitz/Manifest
+++ b/dev-cpp/blitz/Manifest
@@ -1 +1,2 @@
 DIST blitz-1.0.2_p20200524.tar.gz 1297489 BLAKE2B bb2222a63d7763bd9e01b83fd2e895074e2be00bf32617f7ddfbb9e9fc5326daffdb3c5b2a95c257c416238732d53255387df46061a0cca406c33f13747cd060 SHA512 987ee4444b5c2a2d45cb5a66bc7a520e8849461346aab329c14707e53afef7b72325d199b2b619ac7c65c7a1f0995917c6cad2d526166c5ada5e23d0731163aa
+DIST blitz-1.0.3_pre20200524.tar.gz 1297489 BLAKE2B bb2222a63d7763bd9e01b83fd2e895074e2be00bf32617f7ddfbb9e9fc5326daffdb3c5b2a95c257c416238732d53255387df46061a0cca406c33f13747cd060 SHA512 987ee4444b5c2a2d45cb5a66bc7a520e8849461346aab329c14707e53afef7b72325d199b2b619ac7c65c7a1f0995917c6cad2d526166c5ada5e23d0731163aa
diff --git a/dev-cpp/blitz/blitz-1.0.3_pre20200524.ebuild b/dev-cpp/blitz/blitz-1.0.3_pre20200524.ebuild
new file mode 100644
index 000000000..b92ebbcce
--- /dev/null
+++ b/dev-cpp/blitz/blitz-1.0.3_pre20200524.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit cmake python-any-r1
+
+COMMIT="39f885951a9b8b11f931f917935a16066a945056"
+
+DESCRIPTION="Multi-dimensional array library for C++"
+HOMEPAGE="https://github.com/blitzpp/blitz"
+SRC_URI="https://github.com/blitzpp/blitz/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+LICENSE="BSD LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="boost doc test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	doc? ( app-doc/doxygen[dot] )
+"
+DEPEND="
+	boost? ( dev-libs/boost:=[static-libs] )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_DOC=$(usex doc)
+		-DBUILD_TESTING=$(usex test)
+		-DENABLE_SERIALISATION=$(usex boost)
+	)
+	use doc && mycmakeargs+=( -DDISABLE_REFMAN_PDF=ON )
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use doc && cmake_build blitz-doc
+	use test && cmake_build testsuite benchmark examples
+}
+
+src_install() {
+	cmake_src_install
+	if use doc ; then
+		find "${D}" -type f \( -name "*.md5" -o -name "*.map" \) -delete || die
+	fi
+}
diff --git a/dev-cpp/blitz/blitz-9999.ebuild b/dev-cpp/blitz/blitz-9999.ebuild
index 47a9e5d25..7ac6d5688 100644
--- a/dev-cpp/blitz/blitz-9999.ebuild
+++ b/dev-cpp/blitz/blitz-9999.ebuild
@@ -1,40 +1,48 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
-inherit cmake
-CMAKE_MAKEFILE_GENERATOR=emake
+PYTHON_COMPAT=( python3_{7..9} )
 
-DESCRIPTION="multi-dimensional array library for C++"
-HOMEPAGE="https://github.com/blitzpp/blitz"
+inherit cmake git-r3 python-any-r1
 
-if [[ ${PV} == 9999 ]] ; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/blitzpp/blitz"
-else
-	COMMIT=39f885951a9b8b11f931f917935a16066a945056
-	SRC_URI="https://github.com/blitzpp/blitz/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
-	S="${WORKDIR}"/${PN}-${COMMIT}
-	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
-fi
+DESCRIPTION="Multi-dimensional array library for C++"
+HOMEPAGE="https://github.com/blitzpp/blitz"
+EGIT_REPO_URI="https://github.com/blitzpp/blitz"
 
 LICENSE="BSD LGPL-3+"
 SLOT="0"
-IUSE="test"
+IUSE="boost doc test"
 RESTRICT="!test? ( test )"
 
+BDEPEND="
+	${PYTHON_DEPS}
+	doc? ( app-doc/doxygen[dot] )
+"
+DEPEND="
+	boost? ( dev-libs/boost:=[static-libs] )
+"
+
 src_configure() {
 	local mycmakeargs=(
+		-DBUILD_DOC=$(usex doc)
 		-DBUILD_TESTING=$(usex test)
+		-DENABLE_SERIALISATION=$(usex boost)
 	)
+	use doc && mycmakeargs+=( -DDISABLE_REFMAN_PDF=ON )
 	cmake_src_configure
 }
 
 src_compile() {
-	if use test; then
-		cmake_build check-testsuite check-benchmarks check-examples
-	else
-		cmake build
+	cmake_src_compile
+	use doc && cmake_build blitz-doc
+	use test && cmake_build testsuite benchmark examples
+}
+
+src_install() {
+	cmake_src_install
+	if use doc ; then
+		find "${D}" -type f \( -name "*.md5" -o -name "*.map" \) -delete || die
 	fi
 }
diff --git a/dev-cpp/blitz/metadata.xml b/dev-cpp/blitz/metadata.xml
index e97c4322a..c0e5e78aa 100644
--- a/dev-cpp/blitz/metadata.xml
+++ b/dev-cpp/blitz/metadata.xml
@@ -9,4 +9,14 @@
 		<email>sci@gentoo.org</email>
 		<name>Gentoo Science Project</name>
 	</maintainer>
+	<longdescription>
+		Blitz++ is a C++ template class library that provides high-performance
+		multidimensional array containers for scientific compiting.
+	</longdescription>
+	<use>
+		<flag name="boost">Enable serialization support using Boost::Serialization.</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">blitzpp/blitz</remote-id>
+	</upstream>
 </pkgmetadata>