app-admin/webapp-config: enable py3.12

Closes: https://bugs.gentoo.org/929277
Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>

3 files changed, 108 insertions, 2 deletions

diff --git a/app-admin/webapp-config/files/webapp-config-1.55-py3.122-invalid-escape-sequence.patch b/app-admin/webapp-config/files/webapp-config-1.55-py3.122-invalid-escape-sequence.patch
new file mode 100644
index 000000000000..cb1ba1a8593e
--- /dev/null
+++ b/app-admin/webapp-config/files/webapp-config-1.55-py3.122-invalid-escape-sequence.patch
@@ -0,0 +1,11 @@
+--- a/WebappConfig/protect.py
++++ b/WebappConfig/protect.py
+@@ -78,7 +78,7 @@
+ 
+         numbers = []
+         prefix  = self.protect_prefix
+-        rep = re.compile(prefix.replace('.','\.') + '(\d{4})_')
++        rep = re.compile(prefix.replace('.',r'\.') + r'(\d{4})_')
+ 
+         for i in entries:
+             rem = rep.match(i)
diff --git a/app-admin/webapp-config/webapp-config-1.55-r4.ebuild b/app-admin/webapp-config/webapp-config-1.55-r4.ebuild
new file mode 100644
index 000000000000..cc2e8028b578
--- /dev/null
+++ b/app-admin/webapp-config/webapp-config-1.55-r4.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 prefix
+
+if [[ ${PV} = 9999* ]]
+then
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://dev.gentoo.org/~ceamac/${CATEGORY}/${PN}/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+DESCRIPTION="Gentoo's installer for web-based applications"
+HOMEPAGE="https://sourceforge.net/projects/webapp-config/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+portage"
+
+DEPEND="app-text/xmlto
+	sys-apps/gentoo-functions"
+RDEPEND="
+	portage? ( sys-apps/portage[${PYTHON_USEDEP}] )"
+
+PATCHES=(
+	"${FILESDIR}"/webapp-config-1.55-py3.122-invalid-escape-sequence.patch
+)
+
+python_prepare_all() {
+	# make the source from svn mirror the one in the tarball
+	if [[ ${PV} == 9999* ]]; then
+		mkdir ../webapp-config || die "Cannot create temp directory."
+		cp -r * ../webapp-config || die "Cannot copy all into the temp directory."
+		mv ../webapp-config . || die "Cannot move temp directory to its final position."
+
+		# Installation fails if version is 1.55-git
+		sed -e 's/-git//' \
+			-i webapp-config/WebappConfig/version.py \
+			-i WebappConfig/version.py || die "Cannot fix version."
+	fi
+
+	distutils-r1_python_prepare_all
+	eprefixify WebappConfig/eprefix.py config/webapp-config
+}
+
+python_compile_all() {
+	emake -C doc/
+}
+
+python_test() {
+	PYTHONPATH="." "${EPYTHON}" WebappConfig/tests/external.py -v ||
+		die "Testing failed with ${EPYTHON}"
+}
+
+python_install() {
+	# According to this discussion:
+	# http://mail.python.org/pipermail/distutils-sig/2004-February/003713.html
+	# distutils does not provide for specifying two different script install
+	# locations. Since we only install one script here the following should
+	# be ok
+	distutils-r1_python_install --install-scripts="${EPREFIX}/usr/sbin"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	# distutils-r1 installs the scripts in /usr/bin in PEP517 mode
+	mv "${ED}"/usr/bin "${ED}"/usr/sbin || die "Cannot rename scripts directory to /usr/sbin"
+
+	insinto /etc/vhosts
+	doins config/webapp-config
+
+	keepdir /usr/share/webapps
+	keepdir /var/db/webapps
+
+	dodoc AUTHORS
+	doman doc/*.[58]
+}
+
+pkg_postinst() {
+	elog "Now that you have upgraded webapp-config, you **must** update your"
+	elog "config files in /etc/vhosts/webapp-config before you emerge any"
+	elog "packages that use webapp-config."
+}
diff --git a/app-admin/webapp-config/webapp-config-9999.ebuild b/app-admin/webapp-config/webapp-config-9999.ebuild
index 76caefb23e6d..cc2e8028b578 100644
--- a/app-admin/webapp-config/webapp-config-9999.ebuild
+++ b/app-admin/webapp-config/webapp-config-9999.ebuild
@@ -1,10 +1,10 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
 DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_COMPAT=( python3_{10..12} )
 
 inherit distutils-r1 prefix
 
@@ -29,6 +29,10 @@ DEPEND="app-text/xmlto
 RDEPEND="
 	portage? ( sys-apps/portage[${PYTHON_USEDEP}] )"
 
+PATCHES=(
+	"${FILESDIR}"/webapp-config-1.55-py3.122-invalid-escape-sequence.patch
+)
+
 python_prepare_all() {
 	# make the source from svn mirror the one in the tarball
 	if [[ ${PV} == 9999* ]]; then