app-arch/zstd: add 1.5.2-r1 for split-usr too

Apparently I only did 1.5.1?

Bug: https://bugs.gentoo.org/852860
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 67 insertions, 1 deletions

diff --git a/app-arch/zstd/zstd-1.5.1-r3.ebuild b/app-arch/zstd/zstd-1.5.1-r3.ebuild
index 83b2103a30b0..99a923c9e721 100644
--- a/app-arch/zstd/zstd-1.5.1-r3.ebuild
+++ b/app-arch/zstd/zstd-1.5.1-r3.ebuild
@@ -12,7 +12,7 @@ SRC_URI="https://github.com/facebook/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 LICENSE="|| ( BSD GPL-2 )"
 SLOT="0/1"
 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
-IUSE="lz4 static-libs split-usr +threads"
+IUSE="lz4 static-libs +threads"
 
 RDEPEND="app-arch/xz-utils
 	lz4? ( app-arch/lz4 )"
diff --git a/app-arch/zstd/zstd-1.5.2-r1.ebuild b/app-arch/zstd/zstd-1.5.2-r1.ebuild
new file mode 100644
index 000000000000..a55e96f74c14
--- /dev/null
+++ b/app-arch/zstd/zstd-1.5.2-r1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit multilib-minimal toolchain-funcs usr-ldscript
+
+DESCRIPTION="zstd fast compression library"
+HOMEPAGE="https://facebook.github.io/zstd/"
+SRC_URI="https://github.com/facebook/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="|| ( BSD GPL-2 )"
+SLOT="0/1"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="lz4 static-libs +threads"
+
+RDEPEND="app-arch/xz-utils
+	lz4? ( app-arch/lz4 )"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	multilib_copy_sources
+}
+
+mymake() {
+	emake \
+		CC="$(tc-getCC)" \
+		CXX="$(tc-getCXX)" \
+		AR="$(tc-getAR)" \
+		PREFIX="${EPREFIX}/usr" \
+		LIBDIR="${EPREFIX}/usr/$(get_libdir)" \
+		V=1 \
+		"${@}"
+}
+
+multilib_src_compile() {
+	local libzstd_targets=( libzstd{,.a}$(usex threads '-mt' '') )
+
+	mymake -C lib ${libzstd_targets[@]} libzstd.pc
+
+	if multilib_is_native_abi ; then
+		mymake HAVE_LZ4="$(usex lz4 1 0)" zstd
+
+		mymake -C contrib/pzstd
+	fi
+}
+
+multilib_src_install() {
+	mymake -C lib DESTDIR="${D}" install
+
+	if multilib_is_native_abi ; then
+		mymake -C programs DESTDIR="${D}" install
+		gen_usr_ldscript -a zstd
+
+		mymake -C contrib/pzstd DESTDIR="${D}" install
+	fi
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	if ! use static-libs; then
+		find "${ED}" -name "*.a" -delete || die
+	fi
+}