app-cdr/xcdroast: multiple improvements

- Add USE=suid to control optional nonroot-mode as suggested by
Martin Väth, bug 345337 comment 23.
- Disable obsolete version check, patch by Helmut Jarausch
<jarausch at skynet.be>, see
https://archives.gentoo.org/gentoo-user/message/7c5e8669966103a9099efa3a8c808971
- Fix format-security issue, bug 520996.

Package-Manager: portage-2.3.0
Signed-off-by: Andrew Savchenko <bircoph@gentoo.org>

1 files changed, 78 insertions, 0 deletions

diff --git a/app-cdr/xcdroast/xcdroast-0.98_alpha16-r3.ebuild b/app-cdr/xcdroast/xcdroast-0.98_alpha16-r3.ebuild
new file mode 100644
index 000000000000..53aa57c216b6
--- /dev/null
+++ b/app-cdr/xcdroast/xcdroast-0.98_alpha16-r3.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit gnome2-utils
+
+DESCRIPTION="Lightweight cdrtools front-end for CD and DVD writing"
+HOMEPAGE="http://www.xcdroast.org/"
+SRC_URI="mirror://sourceforge/xcdroast/${P/_/}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="nls suid"
+
+RDEPEND=">=x11-libs/gtk+-2:2
+	app-cdr/cdrtools"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${P/_/}
+
+PATCHES=(
+	"${FILESDIR}"/cdda2wav_version.patch
+	"${FILESDIR}"/fix_cddb_hidden_tracks.patch
+	"${FILESDIR}"/io_compile.patch
+	"${FILESDIR}"/io_progressbar_fix.patch
+	"${FILESDIR}"/suid-perms.patch
+	"${FILESDIR}"/disable_version_check.patch
+	"${FILESDIR}"/format-security.patch
+)
+
+src_prepare() {
+	default
+
+	# fix Norwegian locales
+	mv po/{no,nb}.po || die
+	mv po/{no,nb}.gmo || die
+	sed -i -e 's/no/nb/' po/LINGUAS || die
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		$(use_enable suid nonrootmode) \
+		--enable-gtk2 \
+		--disable-dependency-tracking \
+		--mandir=/usr/share/man \
+		--sysconfdir=/etc
+}
+
+src_compile() {
+	emake PREFIX=/usr
+}
+
+src_install() {
+	emake PREFIX=/usr DESTDIR="${D}" install
+	dodoc -r AUTHORS ChangeLog README doc/*
+
+	insinto /usr/share/icons/hicolor/48x48/apps
+	newins xpms/xcdricon.xpm xcdroast.xpm
+
+	make_desktop_entry xcdroast "X-CD-Roast" xcdroast "AudioVideo;DiscBurning"
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}