app-crypt/moolticute: v1.00.1 and 9999 fixes udev, systemd USE flag, EAPI 8

Signed-off-by: Casper Hanegreefs <casinvictusgentoo@proton.me>
Closes: https://github.com/gentoo/gentoo/pull/29137
Closes: https://bugs.gentoo.org/854249
Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>

3 files changed, 81 insertions, 10 deletions

diff --git a/app-crypt/moolticute/Manifest b/app-crypt/moolticute/Manifest
index 46c1f1988c22..2650db9ca083 100644
--- a/app-crypt/moolticute/Manifest
+++ b/app-crypt/moolticute/Manifest
@@ -1 +1,2 @@
 DIST moolticute-0.43.19.tar.gz 5675421 BLAKE2B 8fbe68a86978970768870ac334c38b5cd532e97cb29e03975d6700a98074c51959747c35dee528275b41ef08cf42817f69337c8b93b8c2554729754d4ee818dd SHA512 fb343411854490f8e9bf937728889fc329d2f90274a34bafebacf711b02b3ff04ecad34480b786a59fda07a50f12f572b58fd2c397d46b63dc76df9228ad8711
+DIST moolticute-1.00.1.tar.gz 5911062 BLAKE2B c3e20d4466c6020842447cb2fa54eee309664e8bbbb52aff8582ff7d333c8e5a9a2d286dace8207f62aacc41e0d9a99b733cfc5788dac72933ae7e15dc91a779 SHA512 c1a4ab39abc8360d088f267ae06f69deb135975caaf9224488d5e33127c1a9c1d2c80795d901e83bd13c82f80f1e362acfe59b03ad024b88ef7b8a7d56acd79b
diff --git a/app-crypt/moolticute/moolticute-1.00.1.ebuild b/app-crypt/moolticute/moolticute-1.00.1.ebuild
new file mode 100644
index 000000000000..d7fa4843bf98
--- /dev/null
+++ b/app-crypt/moolticute/moolticute-1.00.1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qmake-utils systemd udev xdg-utils
+
+if [[ ${PV} == 9999* ]]; then
+	EGIT_REPO_URI="https://github.com/mooltipass/moolticute.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/mooltipass/moolticute/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm"
+fi
+
+DESCRIPTION="Mooltipass crossplatform daemon/tools"
+HOMEPAGE="https://github.com/mooltipass/moolticute"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="systemd"
+
+RDEPEND="
+	>=dev-libs/libusb-1.0.20
+	dev-qt/qtdbus:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qttest:5
+	dev-qt/qtwebsockets:5
+	dev-qt/qtwidgets:5
+	systemd? ( sys-apps/systemd )
+	!systemd? ( sys-apps/systemd-utils )
+"
+BDEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+"
+
+src_prepare() {
+	default
+
+	# Fill version.h with package version
+	if [[ ${PV} != 9999* ]]; then
+		sed -i "s/\"git\"/\"v${PV/_/-}\"/" src/version.h || die
+	fi
+}
+
+src_configure() {
+	eqmake5 PREFIX="/usr" Moolticute.pro
+}
+
+src_install() {
+	emake install INSTALL_ROOT="${D}"
+
+	udev_dorules "${FILESDIR}/50-mooltipass.rules"
+	systemd_dounit systemd/moolticuted.service
+	newinitd "${FILESDIR}/moolticuted.init" moolticuted
+}
+
+pkg_postinst() {
+	udev_reload
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	udev_reload
+	xdg_icon_cache_update
+}
diff --git a/app-crypt/moolticute/moolticute-9999.ebuild b/app-crypt/moolticute/moolticute-9999.ebuild
index ea058a356a20..d7fa4843bf98 100644
--- a/app-crypt/moolticute/moolticute-9999.ebuild
+++ b/app-crypt/moolticute/moolticute-9999.ebuild
@@ -1,24 +1,24 @@
-# Copyright 1999-2022 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
+
+inherit qmake-utils systemd udev xdg-utils
 
 if [[ ${PV} == 9999* ]]; then
 	EGIT_REPO_URI="https://github.com/mooltipass/moolticute.git"
 	inherit git-r3
 else
-	SRC_URI="https://github.com/mooltipass/moolticute/archive/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
+	SRC_URI="https://github.com/mooltipass/moolticute/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
 	KEYWORDS="~amd64 ~arm"
 fi
 
-inherit xdg-utils qmake-utils udev
-
 DESCRIPTION="Mooltipass crossplatform daemon/tools"
 HOMEPAGE="https://github.com/mooltipass/moolticute"
 
 LICENSE="GPL-3"
 SLOT="0"
-IUSE=""
+IUSE="systemd"
 
 RDEPEND="
 	>=dev-libs/libusb-1.0.20
@@ -29,13 +29,13 @@ RDEPEND="
 	dev-qt/qttest:5
 	dev-qt/qtwebsockets:5
 	dev-qt/qtwidgets:5
+	systemd? ( sys-apps/systemd )
+	!systemd? ( sys-apps/systemd-utils )
 "
 BDEPEND="${RDEPEND}
 	dev-qt/linguist-tools:5
 "
 
-S="${WORKDIR}/${P/_/-}"
-
 src_prepare() {
 	default
 
@@ -52,8 +52,9 @@ src_configure() {
 src_install() {
 	emake install INSTALL_ROOT="${D}"
 
-	udev_dorules "${FILESDIR}/50-mooltipass.rule"
-	newinitd "${FILESDIR}/moolticuted.init-r1" moolticuted
+	udev_dorules "${FILESDIR}/50-mooltipass.rules"
+	systemd_dounit systemd/moolticuted.service
+	newinitd "${FILESDIR}/moolticuted.init" moolticuted
 }
 
 pkg_postinst() {
@@ -62,5 +63,6 @@ pkg_postinst() {
 }
 
 pkg_postrm() {
+	udev_reload
 	xdg_icon_cache_update
 }