app-crypt/ssss: new package.

SSSS is an implementation of Shamir's Secret Sharing Scheme.

The program suite does both: the generation of shares for a know secret, and
the reconstruction of a secret using user-pro-vided shares.

Closes: https://bugs.gentoo.org/106932
Package-Manager: Portage-2.3.60, Repoman-2.3.12
Signed-off-by: Conrad Kostecki <conrad@kostecki.com>
Closes: https://github.com/gentoo/gentoo/pull/10243
Signed-off-by: Patrice Clement <monsieurp@gentoo.org>

1 files changed, 39 insertions, 0 deletions

diff --git a/app-crypt/ssss/ssss-0.5.ebuild b/app-crypt/ssss/ssss-0.5.ebuild
new file mode 100644
index 000000000000..55fa43d76cb2
--- /dev/null
+++ b/app-crypt/ssss/ssss-0.5.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="Shamir's Secret Sharing Scheme"
+HOMEPAGE="http://point-at-infinity.org/ssss/"
+SRC_URI="http://point-at-infinity.org/${PN}/${P}.tar.gz"
+
+KEYWORDS="~amd64 ~x86"
+LICENSE="GPL-2"
+SLOT="0"
+
+RDEPEND="dev-libs/gmp:0="
+DEPEND="${RDEPEND}"
+BDEPEND="app-doc/xmltoman"
+
+DOCS=( "HISTORY" "THANKS" )
+HTML_DOCS=( "doc.html" "ssss.1.html" )
+
+src_prepare() {
+	default
+
+	tc-export CC
+
+	# Respect users CFLAGS and don't strip, as portage does this part.
+	sed -e 's/-O2/$(CFLAGS)/g' -e '/strip/d' -i Makefile || die
+}
+
+src_install() {
+	dobin ssss-split
+	dosym ssss-split /usr/bin/ssss-combine
+
+	doman ssss.1
+
+	einstalldocs
+}