app-editors/levee: version bump to 4.0, fix clang16 build

- wrote patch to remove all old implicit function declarations, implicit ins, etc (also sent it upstream)
- patch build system to look for libtinfo (bug was also present in 3.5a, but wasn't filed in b.g.o)
- call ./configure.sh with --size=256000 because configure script is using it an a non-standard way

(sam: fix -Wimplicit-int, prestripping)

Closes: https://bugs.gentoo.org/875740
Closes: https://bugs.gentoo.org/870889
Closes: https://bugs.gentoo.org/729264
Closes: https://bugs.gentoo.org/690168
Signed-off-by: Pascal Jäger <pascal.jaeger@leimstift.de>
Closes: https://github.com/gentoo/gentoo/pull/28040
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/app-editors/levee/levee-4.0.ebuild b/app-editors/levee/levee-4.0.ebuild
new file mode 100644
index 000000000000..5212165086a6
--- /dev/null
+++ b/app-editors/levee/levee-4.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Really tiny vi clone, for things like rescue disks"
+HOMEPAGE="https://www.pell.portland.or.us/~orc/Code/levee/"
+SRC_URI="https://www.pell.portland.or.us/~orc/Code/levee/${P}.tar.bz2"
+SRC_URI+=" https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${P}-patches.tar.xz"
+
+LICENSE="levee"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris ~x86-solaris"
+
+RDEPEND="
+	!app-text/lv
+	sys-libs/ncurses:0=
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${WORKDIR}"/${P}-patches
+)
+
+src_configure() {
+	export AC_CPP_PROG="$(tc-getCPP)"
+	export AC_PATH="${PATH}"
+	export AC_LIBDIR="$($(tc-getPKG_CONFIG) --libs ncurses)"
+
+	# --sive=256000 because configure.sh expects size to be a number and not the
+	# tool lize "llvm-size" or "x86_64-pc-linux-gnu-size".
+	# See #729264
+	./configure.sh \
+		--prefix="${PREFIX}"/usr --size=256000 || die "configure failed"
+}
+
+src_compile() {
+	emake \
+		CFLAGS="${CFLAGS} ${LDFLAGS}" \
+		CC="$(tc-getCC)"
+}
+
+src_install() {
+	emake PREFIX="${D}/${EPREFIX}" install
+}