app-emulation/cloud-init: Fix init script permissions

With unfixed 0.7.6_p1212 you got:

$ rc-update add cloud-init-local default
 * rc-update: service `cloud-init-local' is not executeable

Package-Manager: Portage-2.3.3, Repoman-2.3.1

1 files changed, 80 insertions, 0 deletions

diff --git a/app-emulation/cloud-init/cloud-init-0.7.6_p1212-r1.ebuild b/app-emulation/cloud-init/cloud-init-0.7.6_p1212-r1.ebuild
new file mode 100644
index 000000000000..12d4f69ec5de
--- /dev/null
+++ b/app-emulation/cloud-init/cloud-init-0.7.6_p1212-r1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+BZRTGZ=1
+
+inherit distutils-r1 eutils multilib systemd
+
+DESCRIPTION="EC2 initialisation magic"
+HOMEPAGE="https://launchpad.net/cloud-init"
+if [ "x$BZRTGZ" != x1 ]; then
+	SRC_URI="https://launchpad.net/${PN}/trunk/${PV}/+download/${P}.tar.gz"
+else
+	# Launchpad does not provide consistent checksums https://bugs.launchpad.net/launchpad/+bug/1576338
+	# SRC_URI="http://bazaar.launchpad.net/~${PN}-dev/${PN}/trunk/tarball/${PV/*_p} -> ${P}.tar.gz"
+	SRC_URI="mirror://gentoo/${P}.tar.gz http://dev.gentoo.org/~robbat2/distfiles/${P}.tar.gz"
+	S="${WORKDIR}/~cloud-init-dev/cloud-init/trunk/"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+CDEPEND="
+	dev-python/cheetah[${PYTHON_USEDEP}]
+	dev-python/configobj[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/jsonpatch[${PYTHON_USEDEP}]
+	dev-python/oauth[${PYTHON_USEDEP}]
+	dev-python/prettytable[${PYTHON_USEDEP}]
+	dev-python/pyserial[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${CDEPEND}
+		>=dev-python/httpretty-0.7.1[${PYTHON_USEDEP}]
+		dev-python/mocker[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		~dev-python/pep8-1.5.7[${PYTHON_USEDEP}]
+		dev-python/pyflakes[${PYTHON_USEDEP}]
+		sys-apps/iproute2
+	)
+"
+RDEPEND="
+	${CDEPEND}
+	sys-fs/growpart
+	virtual/logger
+"
+
+PATCHES=( "${FILESDIR}/cloud-init-0.7.6_p1212-gentoo.patch" )
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	emake test
+}
+
+python_install() {
+	distutils-r1_python_install "--init-system=sysvinit_openrc"
+}
+
+python_install_all() {
+	keepdir /etc/cloud
+
+	distutils-r1_python_install_all
+	chmod +x "${D}"/etc/init.d/* || die
+
+	insinto /etc/cloud/templates
+	doins "${FILESDIR}/hosts.gentoo.tmpl"
+	insinto /etc/cloud
+	doins "${FILESDIR}/cloud.cfg"
+}