app-misc/iguanaIR: Convert to python-single-r1

1 files changed, 49 insertions, 0 deletions

diff --git a/app-misc/iguanaIR/iguanaIR-1.0.1-r1.ebuild b/app-misc/iguanaIR/iguanaIR-1.0.1-r1.ebuild
new file mode 100644
index 000000000000..debe3dcffa6b
--- /dev/null
+++ b/app-misc/iguanaIR/iguanaIR-1.0.1-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+inherit python-single-r1 user
+
+DESCRIPTION="library for Irman control of Unix software"
+HOMEPAGE="http://iguanaworks.net/index.php"
+SRC_URI="http://iguanaworks.net/downloads/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE=""
+
+# sys-apps/lsb-release is used by the init script for detecting Gentoo
+RDEPEND="dev-libs/popt
+	sys-apps/lsb-release
+	virtual/libusb:0
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}
+	>=dev-lang/swig-2.0.0"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+pkg_setup() {
+	enewgroup iguanair
+	enewuser iguanair -1 -1 -1 'iguanair,usb'
+
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	# Working around bug in SWIG version checking
+	sed -i -e 's:1.3.31:2.0.0:g' configure || die
+}
+
+src_install() {
+	default
+	python_optimize
+
+	dodoc WHY notes.txt protocols.txt
+
+	rm -f docs/{Makefile,pullDocs} || die
+	dodoc -r docs
+}