app-misc/elasticsearch: 6.3.1-r2 bump for new service script

The update to the service script separates command_args and
command_args_background so that the script can be set up to use
supervise-daemon.

Closes: https://bugs.gentoo.org/show_bug.cgi?id=661916
Package-Manager: Portage-2.3.40, Repoman-2.3.9

2 files changed, 145 insertions, 0 deletions

diff --git a/app-misc/elasticsearch/elasticsearch-6.3.1-r2.ebuild b/app-misc/elasticsearch/elasticsearch-6.3.1-r2.ebuild
new file mode 100644
index 000000000000..1b8deddcf8cc
--- /dev/null
+++ b/app-misc/elasticsearch/elasticsearch-6.3.1-r2.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit systemd user
+
+DESCRIPTION="Open Source, Distributed, RESTful, Search Engine"
+HOMEPAGE="https://www.elastic.co/products/elasticsearch"
+SRC_URI="https://artifacts.elastic.co/downloads/${PN}/${PN}-oss-${PV}.tar.gz"
+LICENSE="Apache-2.0 BSD-2 LGPL-3 MIT public-domain"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="virtual/jre:1.8"
+
+pkg_setup() {
+	enewgroup ${PN}
+	enewuser ${PN} -1 /bin/bash /usr/share/${PN} ${PN}
+}
+
+src_prepare() {
+	default
+
+	rm -v bin/*.{bat,exe} LICENSE.txt || die
+}
+
+src_install() {
+	keepdir /etc/${PN}
+	keepdir /etc/${PN}/scripts
+
+	insinto /etc/${PN}
+	doins -r config/.
+	rm -rv config || die
+
+	fowners root:${PN} /etc/${PN}
+	fperms 2750 /etc/${PN}
+
+	insinto /usr/share/${PN}
+	doins -r .
+
+	exeinto /usr/share/${PN}/bin
+	doexe "${FILESDIR}/elasticsearch-systemd-pre-exec"
+
+	chmod +x "${ED}"/usr/share/${PN}/bin/* || die
+
+	keepdir /var/{lib,log}/${PN}
+	fowners ${PN}:${PN} /var/{lib,log}/${PN}
+	fperms 0750 /var/{lib,log}/${PN}
+	dodir /usr/share/${PN}/plugins
+
+	insinto /etc/sysctl.d
+	newins "${FILESDIR}/${PN}.sysctl.d" ${PN}.conf
+
+	newconfd "${FILESDIR}/${PN}.conf.3" ${PN}
+	newinitd "${FILESDIR}/${PN}.init.5" ${PN}
+
+	systemd_install_serviced "${FILESDIR}/${PN}.service.conf"
+	systemd_newtmpfilesd "${FILESDIR}/${PN}.tmpfiles.d" ${PN}.conf
+	systemd_newunit "${FILESDIR}"/${PN}.service.3 ${PN}.service
+}
+
+pkg_postinst() {
+	elog
+	elog "You may create multiple instances of ${PN} by"
+	elog "symlinking the init script:"
+	elog "ln -sf /etc/init.d/${PN} /etc/init.d/${PN}.instance"
+	elog
+	elog "Please make sure you put elasticsearch.yml, log4j2.properties and scripts"
+	elog "from /etc/${PN} into the configuration directory of the instance:"
+	elog "/etc/${PN}/instance"
+	elog
+	ewarn "Please make sure you have proper permissions on /etc/${PN}"
+	ewarn "prior to keystore generation or you may experience startup fails."
+	ewarn "chown root:${PN} /etc/${PN} && chmod 2750 /etc/${PN}"
+	ewarn "chown root:${PN} /etc/${PN}/${PN}.keystore && chmod 0660 /etc/${PN}/${PN}.keystore"
+}
diff --git a/app-misc/elasticsearch/files/elasticsearch.init.5 b/app-misc/elasticsearch/files/elasticsearch.init.5
new file mode 100644
index 000000000000..b9dba6ca5d58
--- /dev/null
+++ b/app-misc/elasticsearch/files/elasticsearch.init.5
@@ -0,0 +1,68 @@
+#!/sbin/openrc-run
+
+name="Elasticsearch"
+description="Elasticsearch Server"
+
+ES_INSTANCE=${RC_SVCNAME#*.}
+
+if [ -n "${ES_INSTANCE}" ] && [ ${RC_SVCNAME} != "elasticsearch" ]; then
+	ES_BASE_PATH="/var/lib/elasticsearch/${ES_INSTANCE}"
+	CONF_DIR="/etc/elasticsearch/${ES_INSTANCE}"
+	DEFAULT_LOG_DIR="/var/log/elasticsearch/${ES_INSTANCE}"
+else
+	ES_BASE_PATH="/var/lib/elasticsearch/_default"
+	CONF_DIR="/etc/elasticsearch"
+	DEFAULT_LOG_DIR="/var/log/elasticsearch/_default"
+fi
+
+ES_HOME=${ES_HOME:="/usr/share/elasticsearch"}
+ES_USER=${ES_USER:="elasticsearch"}
+ES_GROUP=${ES_GROUP:="elasticsearch"}
+ES_STARTUP_SLEEP_TIME=${ES_STARTUP_TIME:=5}
+MAX_OPEN_FILES=${MAX_OPEN_FILES:=65536}
+MAX_MAP_COUNT=${MAX_MAP_COUNT:=262144}
+
+DATA_DIR=${DATA_DIR:="${ES_BASE_PATH}/data"}
+LOG_DIR=${LOG_DIR:="${DEFAULT_LOG_DIR}"}
+
+if [ -f "${CONF_DIR}/elasticsearch.in.sh" ]; then
+    ES_INCLUDE="${CONF_DIR}/elasticsearch.in.sh"
+fi
+
+export ES_INCLUDE
+export JAVA_HOME
+export JAVA_OPTS
+export ES_JVM_OPTIONS
+export ES_JAVA_OPTS
+export ES_STARTUP_SLEEP_TIME
+export ES_PATH_CONF="${CONF_DIR}"
+
+pidfile="/run/elasticsearch/${RC_SVCNAME}.pid"
+
+command="/usr/share/elasticsearch/bin/elasticsearch"
+command_args="-Epath.logs=${LOG_DIR} -Epath.data=${DATA_DIR}"
+command_args_background="--daemonize --pidfile=${pidfile}"
+command_user="${ES_USER}:${ES_GROUP}"
+required_files="${CONF_DIR}/elasticsearch.yml"
+retry="TERM/30/KILL/30"
+
+depend() {
+	use net
+}
+
+start_pre() {
+	if [ -n "${MAX_MAP_COUNT}" -a -f /proc/sys/vm/max_map_count ]; then
+		sysctl -q -w vm.max_map_count=${MAX_MAP_COUNT}
+	fi
+
+	checkpath -d -o "${ES_USER}:${ES_GROUP}" -m750 "/var/lib/elasticsearch"
+	checkpath -d -o "${ES_USER}:${ES_GROUP}" -m750 "/var/log/elasticsearch"
+	checkpath -d -o "${ES_USER}:${ES_GROUP}" -m750 "/run/elasticsearch"
+	checkpath -d -o "${ES_USER}:${ES_GROUP}" -m750 "${ES_BASE_PATH}"
+	checkpath -d -o "${ES_USER}:${ES_GROUP}" -m750 "${LOG_DIR}"
+
+	# fails to start without keystore
+	if [ ! -f "${CONF_DIR}/elasticsearch.keystore" ]; then
+		"${ES_HOME}/bin/elasticsearch-keystore" create
+	fi
+}