app-office/endeavour: Version bump to 43.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

3 files changed, 64 insertions, 3 deletions

diff --git a/app-office/endeavour/Manifest b/app-office/endeavour/Manifest
index 689910024e6c..b4ff5635547b 100644
--- a/app-office/endeavour/Manifest
+++ b/app-office/endeavour/Manifest
@@ -1 +1,2 @@
+DIST Endeavour-43.0.tar.bz2 540310 BLAKE2B f878fa39220300838c350acf8924f1c9d9243ff201bbc478b6947ab482acf886f74fa760359994d27a26aded796d06f64718357c16013523f3c35d23c507fd5e SHA512 2fa544d07113f51e858e75608696bc0fee593237ff0c2681e52e802b08ee497faa2e04283b8e24450cc679fc520433285a949c411697f377fd95bd6e4777abbb
 DIST Endeavour-v42.0.tar.bz2 606645 BLAKE2B f9575eeaa67f837e465cbf8e8790a477c299bea12410ceda3c1f9ab5df69948087c7c8679cee5651eac828b69fe64f2b22ff759c2174f044166b94a25270668c SHA512 6312bad832f864adc3e4e01112efccb9c867b31485460791a1d1cf0d515586e7fdb7dd9dca3790201f764b72c39cff69626794f7020b4b084034fdbd0e07d94a
diff --git a/app-office/endeavour/endeavour-43.0.ebuild b/app-office/endeavour/endeavour-43.0.ebuild
new file mode 100644
index 000000000000..e29cfc5e015d
--- /dev/null
+++ b/app-office/endeavour/endeavour-43.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="Personal task manager"
+HOMEPAGE="https://wiki.gnome.org/Apps/Todo https://gitlab.gnome.org/World/Endeavour"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.gnome.org/World/Endeavour.git"
+	SRC_URI=""
+else
+	SRC_URI="https://gitlab.gnome.org/World/${PN^}/-/archive/${PV}/${PN^}-${PV}.tar.bz2"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}/${PN^}-${PV}"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="+introspection"
+
+RDEPEND="
+	>=dev-libs/glib-2.58.0:2
+	>=gui-libs/gtk-3.92.0:4[introspection?]
+	>=gui-libs/libadwaita-1.2.0:1
+	>=net-libs/gnome-online-accounts-3.2.0:=
+	>=dev-libs/libpeas-1.17
+	>=gnome-extra/evolution-data-server-3.33.2:=[gtk]
+	introspection? ( >=dev-libs/gobject-introspection-1.42:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	# TODO: There aren't any consumers of the introspection outside gnome-todo's own plugins, so maybe we
+	# TODO: should just always build introspection support as an application that needs it for full functionality?
+	local emesonargs=(
+		$(meson_use introspection)
+		-Dtracing=false
+		-Dprofile=default
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
diff --git a/app-office/endeavour/endeavour-9999.ebuild b/app-office/endeavour/endeavour-9999.ebuild
index 97a763cfccef..e29cfc5e015d 100644
--- a/app-office/endeavour/endeavour-9999.ebuild
+++ b/app-office/endeavour/endeavour-9999.ebuild
@@ -13,9 +13,9 @@ if [[ ${PV} == 9999 ]]; then
 	EGIT_REPO_URI="https://gitlab.gnome.org/World/Endeavour.git"
 	SRC_URI=""
 else
-	SRC_URI="https://gitlab.gnome.org/World/${PN^}/-/archive/v${PV}/${PN^}-v${PV}.tar.bz2"
+	SRC_URI="https://gitlab.gnome.org/World/${PN^}/-/archive/${PV}/${PN^}-${PV}.tar.bz2"
 	KEYWORDS="~amd64"
-	S="${WORKDIR}/${PN^}-v${PV}"
+	S="${WORKDIR}/${PN^}-${PV}"
 fi
 
 LICENSE="GPL-3+"
@@ -28,7 +28,6 @@ RDEPEND="
 	>=gui-libs/libadwaita-1.2.0:1
 	>=net-libs/gnome-online-accounts-3.2.0:=
 	>=dev-libs/libpeas-1.17
-	dev-libs/libportal:0=[gtk]
 	>=gnome-extra/evolution-data-server-3.33.2:=[gtk]
 	introspection? ( >=dev-libs/gobject-introspection-1.42:= )
 "