app-text/sdcv: add 0.5.4

Closes: https://bugs.gentoo.org/865915
Signed-off-by: Andrew Savchenko <bircoph@gentoo.org>

2 files changed, 74 insertions, 0 deletions

diff --git a/app-text/sdcv/Manifest b/app-text/sdcv/Manifest
index a57a7f83880a..6bd392c99eb6 100644
--- a/app-text/sdcv/Manifest
+++ b/app-text/sdcv/Manifest
@@ -1 +1,2 @@
 DIST sdcv-0.5.3.tar.gz 62105 BLAKE2B 1424510cff2fa355d17884a31f8136f4c8a7bde071f387dd8a69b1d2d6b9c8e52869cd602b27b9966725370cf128fb62b8628e735f1faa92b78f75215462804f SHA512 73a305baad74d0584912e115d3de7395c8e88745fb69b4e5f1a345061629b0d4e05898bd589e96ce07948d52ba7c508ec4ab77862c8fadca5a2f19c5244e1442
+DIST sdcv-0.5.4.tar.gz 66706 BLAKE2B 9cb481f497483b502bec18765b9cbc31e8dd278e30ebd29005158a724669e171181a82c837b63016b9e88a84973831587d2b137bbbdb2290a89a73d3f0917f81 SHA512 6bae3a2c0f37ed9380f54715626efeea0df75d2525baa583c0915bba4d082d9ece40ee799a1e1bb5d36b7ccebace853653b6fab57d472a432b910f690235ee21
diff --git a/app-text/sdcv/sdcv-0.5.4.ebuild b/app-text/sdcv/sdcv-0.5.4.ebuild
new file mode 100644
index 000000000000..e345ee7b990d
--- /dev/null
+++ b/app-text/sdcv/sdcv-0.5.4.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PLOCALES="cs fr ru sk uk zh_CN zh_TW"
+inherit cmake plocale
+
+DESCRIPTION="Console version of Stardict program"
+HOMEPAGE="https://dushistov.github.io/sdcv/"
+SRC_URI="https://github.com/Dushistov/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="darkterm nls readline test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.36
+	sys-libs/zlib
+	readline? ( sys-libs/readline:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	nls? ( >=sys-devel/gettext-0.14.1 )
+	test? ( app-misc/jq )
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.5.3-t_list.patch"
+	"${FILESDIR}/${PN}-t_interactive.patch"
+)
+
+src_prepare() {
+	if use darkterm; then
+		sed -i 's/;34m/;36m/' src/libwrapper.cpp || die
+	fi
+
+	rm_loc() {
+		rm "po/${1}.po" || die
+	}
+	plocale_for_each_disabled_locale rm_loc
+
+	# do not install locale-specific man pages unless asked to
+	if ! has uk ${LINGUAS-uk}; then
+		sed -ni '/share\/man\/uk/!p' CMakeLists.txt || die
+	fi
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_NLS="$(usex nls)"
+		-DWITH_READLINE="$(usex readline)"
+		-DBUILD_TESTS="$(usex test ON OFF)"
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use nls && cmake_src_compile lang
+}
+
+src_install() {
+	# with USE=nls, but empty intersection of LINGUAS and list of
+	# supported translations, this directory is required, see bug 583386
+	mkdir -p "${BUILD_DIR}/locale"
+	cmake_src_install
+	dodoc doc/DICTFILE_FORMAT
+}