dev-ada/gnatcoll-bindings: enable build with gnat-gpl-2019

Signed-off-by: Alfredo Tupone <tupone@gentoo.org>
Package-Manager: Portage-2.3.62, Repoman-2.3.11

2 files changed, 81 insertions, 0 deletions

diff --git a/dev-ada/gnatcoll-bindings/gnatcoll-bindings-2018-r1.ebuild b/dev-ada/gnatcoll-bindings/gnatcoll-bindings-2018-r1.ebuild
new file mode 100644
index 000000000000..dcebe0e138eb
--- /dev/null
+++ b/dev-ada/gnatcoll-bindings/gnatcoll-bindings-2018-r1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+inherit multilib multiprocessing python-single-r1
+
+MYP=${PN}-gpl-${PV}
+
+DESCRIPTION="GNAT Component Collection"
+HOMEPAGE="http://libre.adacore.com"
+SRC_URI="http://mirrors.cdn.adacore.com/art/5b0ce9cfc7a4475261f97ca5
+	-> ${MYP}-src.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnat_2016 gnat_2017 +gnat_2018 gnat_2019 gmp iconv python readline +shared
+	static-libs static-pic syslog"
+
+RDEPEND="python? ( ${PYTHON_DEPS} )
+	dev-ada/gnatcoll-core[gnat_2016=,gnat_2017=,gnat_2018=,gnat_2019=]
+	dev-ada/gnatcoll-core[shared?,static-libs?,static-pic?]
+	gmp? ( dev-libs/gmp:* )"
+DEPEND="${RDEPEND}
+	dev-ada/gprbuild[gnat_2016=,gnat_2017=,gnat_2018=,gnat_2019=]"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+S="${WORKDIR}"/${MYP}-src
+
+src_compile() {
+	build () {
+		gprbuild -j$(makeopts_jobs) -m -p -v \
+			-XGPR_BUILD=$2 -XGNATCOLL_CORE_BUILD=$2 \
+			-XLIBRARY_TYPE=$2 -P $1/gnatcoll_$1.gpr -XBUILD="PROD" \
+			-XGNATCOLL_ICONV_OPT= -XGNATCOLL_PYTHON_CFLAGS="-I$(python_get_includedir)" \
+			-XGNATCOLL_PYTHON_LIBS=$(python_get_library_path) \
+			-cargs:Ada ${ADAFLAGS} -cargs:C ${CFLAGS} || die "gprbuild failed"
+	}
+	for kind in shared static-libs static-pic ; do
+		if use $kind; then
+			lib=${kind%-libs}
+			lib=${lib/shared/relocatable}
+			for dir in gmp iconv python readline syslog ; do
+				if use $dir; then
+					build $dir $lib
+				fi
+			done
+		fi
+	done
+}
+
+src_install() {
+	build () {
+		gprinstall -p -f -XBUILD=PROD --prefix="${D}"/usr -XLIBRARY_TYPE=$2 \
+			-XGPR_BUILD=$2 -XGNATCOLL_CORE_BUILD=$2 \
+			-XGNATCOLL_ICONV_OPT= -P $1/gnatcoll_$1.gpr --build-name=$2
+	}
+	for kind in shared static-libs static-pic ; do
+		if use $kind; then
+			lib=${kind%-libs}
+			lib=${lib/shared/relocatable}
+			for dir in gmp iconv python readline syslog ; do
+				if use $dir; then
+					build $dir $lib
+				fi
+			done
+		fi
+	done
+	if use iconv; then
+		sed -i \
+			-e "s:GNATCOLL_ICONV_BUILD:LIBRARY_TYPE:" \
+			"${D}"/usr/share/gpr/gnatcoll_iconv.gpr \
+			|| die
+	fi
+	rm -r "${D}"/usr/share/gpr/manifests || die
+	einstalldocs
+}
diff --git a/dev-ada/gnatcoll-bindings/metadata.xml b/dev-ada/gnatcoll-bindings/metadata.xml
index 2c51f48ee668..ec2b20f2032a 100644
--- a/dev-ada/gnatcoll-bindings/metadata.xml
+++ b/dev-ada/gnatcoll-bindings/metadata.xml
@@ -9,6 +9,7 @@
 		<flag name="gnat_2016">Compile with dev-lang/gnat-gpl-2016</flag>
 		<flag name="gnat_2017">Compile with dev-lang/gnat-gpl-2017</flag>
 		<flag name="gnat_2018">Compile with dev-lang/gnat-gpl-2018</flag>
+		<flag name="gnat_2019">Compile with dev-lang/gnat-gpl-2019</flag>
 		<flag name="shared">Build shared library</flag>
 		<flag name="static-pic">Build shared library</flag>
 	</use>