dev-db/tora: update EAPI 6 -> 8

Closes: https://bugs.gentoo.org/835915
Signed-off-by: David Seifert <soap@gentoo.org>

1 files changed, 22 insertions, 28 deletions

diff --git a/dev-db/tora/tora-3.2-r1.ebuild b/dev-db/tora/tora-3.2-r2.ebuild
index b653ad25405a..0e6cac5f8c23 100644
--- a/dev-db/tora/tora-3.2-r1.ebuild
+++ b/dev-db/tora/tora-3.2-r2.ebuild
@@ -1,11 +1,11 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=8
 
-inherit cmake-utils desktop xdg-utils
+inherit cmake desktop toolchain-funcs xdg
 
-if [[ ${PV} == 9999 ]]; then
+if [[ ${PV} == *9999 ]]; then
 	EGIT_REPO_URI="https://github.com/tora-tool/tora"
 	inherit git-r3
 else
@@ -15,11 +15,11 @@ fi
 
 DESCRIPTION="SQL IDE for Oracle, MySQL and PostgreSQL dbs"
 HOMEPAGE="https://github.com/tora-tool/tora/wiki"
-IUSE="doc mysql oracle +postgres"
-REQUIRED_USE="|| ( mysql oracle postgres )"
 
-SLOT="0"
 LICENSE="GPL-2"
+SLOT="0"
+IUSE="doc mysql oracle +postgres"
+REQUIRED_USE="|| ( mysql oracle postgres )"
 
 RDEPEND="
 	dev-libs/ferrisloki
@@ -33,19 +33,23 @@ RDEPEND="
 	oracle? ( dev-db/oracle-instantclient )
 	postgres? ( dev-db/postgresql:* )
 "
-DEPEND="${RDEPEND}
+DEPEND="
+	${RDEPEND}
+	dev-libs/boost
+"
+BDEPEND="
 	dev-qt/linguist-tools:5
 	virtual/pkgconfig
 	doc? ( app-doc/doxygen )
 "
 
 PATCHES=(
-	"${FILESDIR}/${P}-missing-header.patch"
-	"${FILESDIR}/${P}-qt-5.11.0.patch"
+	"${FILESDIR}"/${P}-missing-header.patch
+	"${FILESDIR}"/${P}-qt-5.11.0.patch
 )
 
 src_prepare() {
-	cmake-utils_src_prepare
+	cmake_src_prepare
 
 	# fixed in master, only care about recent qscintilla lib name:
 	sed -e "/FIND_LIBRARY(QSCINTILLA_LIBRARY/s/qt5scintilla2/qscintilla2_qt5/" \
@@ -68,29 +72,19 @@ src_configure() {
 		-DWANT_INTERNAL_LOKI=OFF
 		-DWANT_INTERNAL_QSCINTILLA=OFF
 		-DWANT_RPM=OFF
-		-DLOKI_LIBRARY="$($(tc-getPKG_CONFIG) --variable=libdir ferrisloki)/libferrisloki.so"
-		-DLOKI_INCLUDE_DIR="$($(tc-getPKG_CONFIG) --variable=includedir ferrisloki)/FerrisLoki"
-		$(cmake-utils_use_find_package doc Doxygen)
+		-DLOKI_LIBRARY="$($(tc-getPKG_CONFIG) --variable=libdir ferrisloki || die)/libferrisloki.so"
+		-DLOKI_INCLUDE_DIR="$($(tc-getPKG_CONFIG) --variable=includedir ferrisloki || die)/FerrisLoki"
+		$(cmake_use_find_package doc Doxygen)
 		-DENABLE_ORACLE=$(usex oracle)
 		-DUSE_PCH=OFF
 		-DENABLE_PGSQL=$(usex postgres)
 	)
-	cmake-utils_src_configure
+	cmake_src_configure
 }
 
 src_install() {
-	cmake-utils_src_install
-
-	doicon src/icons/${PN}.xpm || die
-	domenu src/${PN}.desktop || die
-}
-
-pkg_postinst() {
-	xdg_mimeinfo_database_update
-	xdg_desktop_database_update
-}
+	cmake_src_install
 
-pkg_postrm() {
-	xdg_mimeinfo_database_update
-	xdg_desktop_database_update
+	doicon src/icons/tora.xpm || die
+	domenu src/tora.desktop || die
 }