dev-embedded/avrdude: Revert "drop 9999", modernise 9999

Apparently this is still useful for some folks
as upstream haven't made a release in a good
while and some new functionality exists only
in VCS.

This reverts commit ccb6e0fa1513ad869ff7935ab80bf6e477464705.

Reported-by: zgu
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 98 insertions, 8 deletions

diff --git a/dev-embedded/avrdude/avrdude-6.3-r1.ebuild b/dev-embedded/avrdude/avrdude-6.3-r1.ebuild
index eedc4b7b5069..701d5da2a71a 100644
--- a/dev-embedded/avrdude/avrdude-6.3-r1.ebuild
+++ b/dev-embedded/avrdude/avrdude-6.3-r1.ebuild
@@ -1,21 +1,30 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=8
+EAPI=7
 
 inherit toolchain-funcs
 
+MY_DOC_PV=6.3
 DESCRIPTION="AVR Downloader/UploaDEr"
 HOMEPAGE="https://savannah.nongnu.org/projects/avrdude"
-SRC_URI="mirror://nongnu/${PN}/${P}.tar.gz
-	doc? (
-		mirror://nongnu/${PN}/${PN}-doc-${PV}.tar.gz
-		mirror://nongnu/${PN}/${PN}-doc-${PV}.pdf
-	)"
+
+if [[ ${PV} == *9999* ]] ; then
+	ESVN_REPO_URI="svn://svn.savannah.nongnu.org/avrdude/trunk/avrdude"
+	inherit autotools subversion
+else
+	SRC_URI="mirror://nongnu/${PN}/${P}.tar.gz"
+
+	KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+fi
+
+SRC_URI+=" doc? (
+	mirror://nongnu/${PN}/${PN}-doc-${MY_DOC_PV}.tar.gz
+	mirror://nongnu/${PN}/${PN}-doc-${MY_DOC_PV}.pdf
+)"
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
 IUSE="doc ftdi ncurses readline"
 
 RDEPEND="
@@ -28,12 +37,20 @@ RDEPEND="
 "
 DEPEND="${RDEPEND}"
 
+src_prepare() {
+	default
+
+	[[ ${PV} == *9999* ]] && eautoreconf
+}
+
 src_configure() {
 	# somehow this doesnt get set when cross-compiling and breaks build
 	tc-export AR
+
 	export ac_cv_lib_ftdi_ftdi_usb_get_strings=$(usex ftdi)
 	export ac_cv_lib_ncurses_tputs=$(usex ncurses)
 	export ac_cv_lib_readline_readline=$(usex readline)
+
 	econf --disable-static
 }
 
@@ -48,7 +65,7 @@ src_install() {
 	default
 
 	if use doc ; then
-		newdoc "${DISTDIR}/${PN}-doc-${PV}.pdf" avrdude.pdf
+		newdoc "${DISTDIR}/${PN}-doc-${MY_DOC_PV}.pdf" avrdude.pdf
 		dodoc -r "${WORKDIR}/avrdude-html/"
 	fi
 
diff --git a/dev-embedded/avrdude/avrdude-9999.ebuild b/dev-embedded/avrdude/avrdude-9999.ebuild
new file mode 100644
index 000000000000..701d5da2a71a
--- /dev/null
+++ b/dev-embedded/avrdude/avrdude-9999.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+MY_DOC_PV=6.3
+DESCRIPTION="AVR Downloader/UploaDEr"
+HOMEPAGE="https://savannah.nongnu.org/projects/avrdude"
+
+if [[ ${PV} == *9999* ]] ; then
+	ESVN_REPO_URI="svn://svn.savannah.nongnu.org/avrdude/trunk/avrdude"
+	inherit autotools subversion
+else
+	SRC_URI="mirror://nongnu/${PN}/${P}.tar.gz"
+
+	KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+fi
+
+SRC_URI+=" doc? (
+	mirror://nongnu/${PN}/${PN}-doc-${MY_DOC_PV}.tar.gz
+	mirror://nongnu/${PN}/${PN}-doc-${MY_DOC_PV}.pdf
+)"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="doc ftdi ncurses readline"
+
+RDEPEND="
+	virtual/libelf
+	virtual/libusb:1
+	virtual/libusb:0
+	ftdi? ( dev-embedded/libftdi:= )
+	ncurses? ( sys-libs/ncurses:0= )
+	readline? ( sys-libs/readline:0= )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	[[ ${PV} == *9999* ]] && eautoreconf
+}
+
+src_configure() {
+	# somehow this doesnt get set when cross-compiling and breaks build
+	tc-export AR
+
+	export ac_cv_lib_ftdi_ftdi_usb_get_strings=$(usex ftdi)
+	export ac_cv_lib_ncurses_tputs=$(usex ncurses)
+	export ac_cv_lib_readline_readline=$(usex readline)
+
+	econf --disable-static
+}
+
+src_compile() {
+	# The automake target for these files does not use tempfiles or create
+	# these atomically, confusing a parallel build. So we force them first.
+	emake lexer.c config_gram.c config_gram.h
+	emake
+}
+
+src_install() {
+	default
+
+	if use doc ; then
+		newdoc "${DISTDIR}/${PN}-doc-${MY_DOC_PV}.pdf" avrdude.pdf
+		dodoc -r "${WORKDIR}/avrdude-html/"
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
+}