dev-lang/swi-prolog: bump development version

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Keri Harris <keri@gentoo.org>

2 files changed, 104 insertions, 0 deletions

diff --git a/dev-lang/swi-prolog/Manifest b/dev-lang/swi-prolog/Manifest
index ea6b01653fd7..d5a68fea9223 100644
--- a/dev-lang/swi-prolog/Manifest
+++ b/dev-lang/swi-prolog/Manifest
@@ -2,3 +2,4 @@ DIST swipl-8.0.3.tar.gz 10418553 BLAKE2B d7d381a3070384164f9788060e1c431cc4658dd
 DIST swipl-8.1.27.tar.gz 10911864 BLAKE2B d65dfe1103fd82adfbb81251c45b085c70d7c494ca0f484dc2d14b74658418272d679107981ac04814f1151ef5c71ec1d68176ae792540936c2047572e521e21 SHA512 f5cc8ed07c28a3f6a67213f66647e0e8fef80fd31871852283ac99d4b137da560734c8f0cf6c12563b0576f8fce8def752caa2b9f84619ca8a8c11d42c5949b9
 DIST swipl-8.1.28.tar.gz 10905268 BLAKE2B 91d2838b74384a78f32649a84c64aa0d9c66495bd45c6729f15e7a8f894521996827da792eb5449f78ed3778722426a02aad54221f3bea5d505b1e639cefe300 SHA512 0ea387aaabcc028362ee42a87b72237b59f6ddc8fccadeef81f0480136a6b8492a7420a3209ef7501425fa16fd362915c7d828a6f1bd3ff84b537ecba802ade7
 DIST swipl-8.1.29.tar.gz 10902999 BLAKE2B 2163cbe4ce772fc0ba8dc961aabf5d3940e0b735bb4688050041d8bcbe6c052d5308696cbbcec49ecc100db44faa960fd8520d89a934f9b05994170c5fab5bff SHA512 0aeaa093a0cc39375b25f2ac642dec99c50aad82c5fa0069be6c5c7bf3ba53deb20e4c887e47649874305e91e7c963bab2515ab8a48db6cdfae6e4560aee063f
+DIST swipl-8.1.30.tar.gz 10921576 BLAKE2B ce163c7600554e5a2f62a75c4fc17444c115adda96527068f6ee707f390c9383e8e2f7a24cf493903edd895fd5ece186b7645cad50d44805d57617c7182ba120 SHA512 1b8be8d4f987bb4ce4e3ea82ab02c0e89f2fba68818a15bf2b86593ba53724005cf617f69e41a4394009dcd0abda84103cba4d4bb3ae562b29d942d0f55cad9a
diff --git a/dev-lang/swi-prolog/swi-prolog-8.1.30.ebuild b/dev-lang/swi-prolog/swi-prolog-8.1.30.ebuild
new file mode 100644
index 000000000000..2293c183ae1c
--- /dev/null
+++ b/dev-lang/swi-prolog/swi-prolog-8.1.30.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils eutils flag-o-matic multilib
+
+PATCHSET_VER="0"
+
+DESCRIPTION="versatile implementation of the Prolog programming language"
+HOMEPAGE="http://www.swi-prolog.org/"
+SRC_URI="http://www.swi-prolog.org/download/devel/src/swipl-${PV}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="archive berkdb debug doc +gmp java +libedit libressl minimal odbc pcre qt5 readline ssl test uuid X yaml"
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-libs/ncurses:=
+	sys-libs/zlib
+	archive? ( app-arch/libarchive )
+	berkdb? ( >=sys-libs/db-4:= )
+	odbc? ( dev-db/unixODBC )
+	pcre? ( dev-libs/libpcre )
+	readline? ( sys-libs/readline:= )
+	libedit? ( dev-libs/libedit )
+	gmp? ( dev-libs/gmp:0 )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0 )
+		libressl? ( dev-libs/libressl )
+	)
+	java? ( >=virtual/jdk-1.7:= )
+	uuid? ( dev-libs/ossp-uuid )
+	qt5? (
+		dev-qt/qtwidgets:5
+		dev-qt/qtgui:5
+	)
+	X? (
+		virtual/jpeg:0
+		x11-libs/libX11
+		x11-libs/libXft
+		x11-libs/libXinerama
+		x11-libs/libXpm
+		x11-libs/libXt
+		x11-libs/libICE
+		x11-libs/libSM )
+	yaml? ( dev-libs/libyaml )"
+
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+	java? ( test? ( =dev-java/junit-3.8* ) )"
+
+S="${WORKDIR}/swipl-${PV}"
+BUILD_DIR="${S}/build"
+CMAKE_USE_DIR="${S}"
+
+src_prepare() {
+	if [[ -d "${WORKDIR}"/${PV} ]] ; then
+		eapply "${WORKDIR}"/${PV}
+	fi
+	eapply_user
+
+	sed -i -e "s|\(SWIPL_INSTALL_PREFIX\)   lib/.*)|\1   $(get_libdir)/swipl)|" CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+	use debug && append-flags -DO_DEBUG
+
+	mycmakeargs=(
+		-DSWIPL_INSTALL_PREFIX=$(get_libdir)/swipl
+		-DUSE_GMP=$(usex gmp)
+		-DINSTALL_DOCUMENTATION=$(use doc && usex archive)
+		-DSWIPL_PACKAGES_BASIC=$(usex !minimal)
+		-DSWIPL_PACKAGES_ARCHIVE=$(usex archive)
+		-DSWIPL_PACKAGES_ODBC=$(usex odbc)
+		-DSWIPL_PACKAGES_BDB=$(usex berkdb)
+		-DSWIPL_PACKAGES_PCRE=$(usex pcre)
+		-DSWIPL_PACKAGES_YAML=$(usex yaml)
+		-DSWIPL_PACKAGES_SSL=$(usex ssl)
+		-DSWIPL_PACKAGES_JAVA=$(usex java)
+		-DSWIPL_PACKAGES_QT=$(usex qt5)
+		-DSWIPL_PACKAGES_X=$(usex X)
+		-DSWIPL_PACKAGES_TERM=$(if use libedit || use readline; then echo yes; else echo no; fi)
+		)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	XDG_CONFIG_DIRS="${HOME}" \
+	XDG_DATA_DIRS="${HOME}" \
+		cmake-utils_src_compile
+}
+
+src_test() {
+	USE_PUBLIC_NETWORK_TESTS=false \
+	USE_ODBC_TESTS=false \
+		cmake-utils_src_test -V
+}