dev-libs/ding-libs: Port to EAPI 7

Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: David Seifert <soap@gentoo.org>

1 files changed, 36 insertions, 0 deletions

diff --git a/dev-libs/ding-libs/ding-libs-0.6.1-r1.ebuild b/dev-libs/ding-libs/ding-libs-0.6.1-r1.ebuild
new file mode 100644
index 000000000000..5ab407b043ee
--- /dev/null
+++ b/dev-libs/ding-libs/ding-libs-0.6.1-r1.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib-minimal
+
+DESCRIPTION="set of utility libraries (mostly used by sssd)"
+HOMEPAGE="https://pagure.io/SSSD/ding-libs"
+SRC_URI="https://releases.pagure.org/SSSD/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-3 GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="test? ( dev-libs/check )"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/0000-INI-Fix-detection-of-error-messages.patch
+	"${FILESDIR}"/0001-path_utils_ut-allow-single-as-well.patch
+	"${FILESDIR}"/0002-validators_ut_check-Fix-fail-with-new-glibc.patch
+)
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf --disable-static
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	# no static archives
+	find "${ED}" -name '*.la' -delete || die
+}