proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 79 insertions, 0 deletions

diff --git a/dev-libs/libmateweather/libmateweather-1.8.0.ebuild b/dev-libs/libmateweather/libmateweather-1.8.0.ebuild
new file mode 100644
index 000000000000..0d9aeb45b457
--- /dev/null
+++ b/dev-libs/libmateweather/libmateweather-1.8.0.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+GCONF_DEBUG="yes"
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python2_7 )
+
+inherit autotools gnome2 python-r1 versionator
+
+MATE_BRANCH="$(get_version_component_range 1-2)"
+
+SRC_URI="http://pub.mate-desktop.org/releases/${MATE_BRANCH}/${P}.tar.xz"
+DESCRIPTION="MATE library to access weather information from online services"
+HOMEPAGE="http://mate-desktop.org"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+
+IUSE="python"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND=">=dev-libs/glib-2.13:2[${PYTHON_USEDEP}]
+	>=dev-libs/libxml2-2.6:2
+	>=net-libs/libsoup-2.34:2.4
+	>=sys-libs/timezone-data-2010k:0
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-2.11:2
+	virtual/libintl:0
+
+	python? (
+		${PYTHON_DEPS}
+		>=dev-python/pygobject-2:2[${PYTHON_USEDEP}]
+		>=dev-python/pygtk-2:2[${PYTHON_USEDEP}]
+	)"
+
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.40.3:*
+	>=mate-base/mate-common-1.8:0
+	sys-devel/gettext:*
+	virtual/pkgconfig:*"
+
+my_command() {
+	if use python ; then
+		python_foreach_impl run_in_build_dir $@
+	else
+		$@
+	fi
+}
+
+src_prepare() {
+	# Fix undefined use of MKDIR_P in python/Makefile.am.
+	epatch "${FILESDIR}"/${PN}-1.6.1-fix-mkdirp.patch
+	eautoreconf
+
+	use python && python_copy_sources
+	my_command gnome2_src_prepare
+}
+
+src_configure() {
+	my_command gnome2_src_configure \
+		--enable-locations-compression \
+		--disable-all-translations-in-one-xml \
+		$(use_enable python)
+}
+
+src_compile() {
+	my_command gnome2_src_compile
+}
+
+DOCS="AUTHORS ChangeLog NEWS"
+
+src_install() {
+	my_command gnome2_src_install
+}