proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 72 insertions, 0 deletions

diff --git a/dev-libs/xqilla/xqilla-2.3.0.ebuild b/dev-libs/xqilla/xqilla-2.3.0.ebuild
new file mode 100644
index 000000000000..fc1a8a735f72
--- /dev/null
+++ b/dev-libs/xqilla/xqilla-2.3.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="4"
+
+inherit autotools base
+
+MY_P="XQilla-${PV}"
+
+DESCRIPTION="An XQuery and XPath 2 library and command line utility written in C++"
+HOMEPAGE="http://xqilla.sourceforge.net/HomePage"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+LICENSE="Apache-2.0 BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc examples faxpp htmltidy static-libs"
+
+# XQilla bundles two libraries:
+# - mapm, heavily patched
+# - yajl, moderately patched
+# There's currently no way to unbundle those
+
+RDEPEND=">=dev-libs/xerces-c-3.1.1
+	faxpp? ( dev-libs/faxpp )
+	htmltidy? ( app-text/htmltidy )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )"
+
+PATCHES=(
+	"${FILESDIR}/2.2.4-respect-ldflags-no-rpath.patch"
+)
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	base_src_prepare
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-xerces="${EPREFIX}"/usr \
+		$(use_enable debug) \
+		$(use_with htmltidy tidy /usr) \
+		$(use_with faxpp faxpp /usr) \
+		$(use_enable static-libs static)
+}
+
+src_compile() {
+	default
+
+	if use doc; then
+		emake docs || die "emake docs failed"
+		emake devdocs || die "emake devdocs failed"
+	fi
+}
+
+src_install () {
+	default
+
+	use static-libs || rm -rf "${ED}"/usr/lib*/*.la
+
+	if use doc; then
+		cd docs
+		dohtml -r dev-api dom3-api simple-api
+	fi
+	if use examples ; then
+		insinto /usr/share/doc/${PF}/examples
+		doins -r "${S}"/src/samples/*
+	fi
+}