dev-libs/judy: Drop ltprune inherit; Revbump for EAPI 7

Signed-off-by: Brian Evans <grknight@gentoo.org>

2 files changed, 36 insertions, 2 deletions

diff --git a/dev-libs/judy/judy-1.0.5-r2.ebuild b/dev-libs/judy/judy-1.0.5-r2.ebuild
index 9e0e3bc742e4..548bcefdca81 100644
--- a/dev-libs/judy/judy-1.0.5-r2.ebuild
+++ b/dev-libs/judy/judy-1.0.5-r2.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=6
 
-inherit autotools ltprune multilib-minimal
+inherit autotools multilib-minimal
 
 DESCRIPTION="A C library that implements a dynamic array"
 HOMEPAGE="http://judy.sourceforge.net/"
@@ -30,5 +30,5 @@ multilib_src_configure() {
 
 multilib_src_install_all(){
 	einstalldocs
-	prune_libtool_files
+	find "${ED}" -name '*.la' -delete || die
 }
diff --git a/dev-libs/judy/judy-1.0.5-r3.ebuild b/dev-libs/judy/judy-1.0.5-r3.ebuild
new file mode 100644
index 000000000000..3c9b879d9d3d
--- /dev/null
+++ b/dev-libs/judy/judy-1.0.5-r3.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools multilib-minimal
+
+DESCRIPTION="A C library that implements a dynamic array"
+HOMEPAGE="http://judy.sourceforge.net/"
+SRC_URI="mirror://sourceforge/judy/Judy-${PV}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="static-libs"
+DOCS=( AUTHORS ChangeLog README )
+
+src_prepare() {
+	eapply -p0 "${FILESDIR}/${P}-parallel-make.patch"
+	eapply "${FILESDIR}/${P}-gcc49.patch"
+	sed -i 's/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/g' configure.ac || die
+	eapply_user
+	eautoreconf
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE=${BUILD_DIR} econf $(use_enable static-libs static)
+}
+
+multilib_src_install_all(){
+	einstalldocs
+	find "${ED}" -name '*.la' -delete || die
+}