dev-python/PyQtWebEngine: add 5.15.2

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Davide Pesavento <pesa@gentoo.org>

1 files changed, 75 insertions, 0 deletions

diff --git a/dev-python/PyQtWebEngine/PyQtWebEngine-5.15.2.ebuild b/dev-python/PyQtWebEngine/PyQtWebEngine-5.15.2.ebuild
new file mode 100644
index 000000000000..94183f43f9bb
--- /dev/null
+++ b/dev-python/PyQtWebEngine/PyQtWebEngine-5.15.2.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+inherit python-r1 qmake-utils
+
+DESCRIPTION="Python bindings for QtWebEngine"
+HOMEPAGE="https://www.riverbankcomputing.com/software/pyqtwebengine/intro"
+
+MY_P=${PN}-${PV/_pre/.dev}
+if [[ ${PV} == *_pre* ]]; then
+	SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${MY_P}.tar.gz"
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="debug"
+
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-python/PyQt5-5.14[gui,network,printsupport,ssl,webchannel,widgets,${PYTHON_USEDEP}]
+	>=dev-python/PyQt5-sip-4.19.22:=[${PYTHON_USEDEP}]
+	dev-qt/qtcore:5
+	dev-qt/qtwebengine:5[widgets]
+"
+DEPEND="${RDEPEND}
+	>=dev-python/sip-4.19.22[${PYTHON_USEDEP}]
+"
+
+S=${WORKDIR}/${MY_P}
+
+src_configure() {
+	configuration() {
+		local myconf=(
+			"${PYTHON}"
+			"${S}"/configure.py
+			--qmake="$(qt5_get_bindir)"/qmake
+			$(usex debug '--debug --trace' '')
+			--verbose
+		)
+		echo "${myconf[@]}"
+		"${myconf[@]}" || die
+
+		# Fix parallel install failure
+		sed -i -e '/INSTALLS += distinfo/i distinfo.depends = install_subtargets install_pep484_stubs install_api' \
+			${PN}.pro || die
+
+		# Run eqmake to respect toolchain and build flags
+		eqmake5 -recursive ${PN}.pro
+	}
+	python_foreach_impl run_in_build_dir configuration
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	installation() {
+		emake INSTALL_ROOT="${D}" install
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir installation
+
+	einstalldocs
+}