dev-python/cassandra-driver: new package 2.7.2

Package-Manager: portage-2.2.23

3 files changed, 104 insertions, 0 deletions

diff --git a/dev-python/cassandra-driver/Manifest b/dev-python/cassandra-driver/Manifest
new file mode 100644
index 000000000000..9592b7c5666c
--- /dev/null
+++ b/dev-python/cassandra-driver/Manifest
@@ -0,0 +1 @@
+DIST cassandra-driver-2.7.2.tar.gz 413805 SHA256 dcff93964334902c5707a3024b500c063ec254da61adae9ab8b3824d56088cd5 SHA512 7548764f2a315dc6f6d4a00138767e6ba6b453a7d7ff19c0913f8c931ae6cb163092644c2d24b87e9efefcdf8568d7e84dccf9f990ab498f187a1bb0c498f415 WHIRLPOOL 219a4017d0e129d14aa2cf87ac5f4875c671777e8064cbaf240f84b22df171b3be902fabeec8327e4064b6417c8b44d12b4d9d462bc491d71ae6ec3149612898
diff --git a/dev-python/cassandra-driver/cassandra-driver-2.7.2.ebuild b/dev-python/cassandra-driver/cassandra-driver-2.7.2.ebuild
new file mode 100644
index 000000000000..679696c37874
--- /dev/null
+++ b/dev-python/cassandra-driver/cassandra-driver-2.7.2.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 python3_4 )
+
+inherit distutils-r1 eutils vcs-snapshot
+
+DESCRIPTION="DataStax python driver for Apache Cassandra"
+HOMEPAGE="https://github.com/datastax/python-driver https://pypi.python.org/pypi/cassandra-driver/${PV}"
+SRC_URI="https://github.com/datastax/python-driver/archive/${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="Apache-2.0"
+
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+cython doc +libev +murmur test"
+
+RDEPEND="
+	$(python_gen_cond_dep '=dev-python/futures-2.2.0[${PYTHON_USEDEP}]' python2_7)
+	>=dev-python/six-1.6[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	cython? (
+		>=dev-python/cython-0.20[${PYTHON_USEDEP}]
+	)
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	libev? (
+		dev-libs/libev
+	)
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		~dev-python/mock-1.0.1[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/sure[${PYTHON_USEDEP}]
+	)
+"
+
+python_configure_all() {
+	mydistutilsargs=( $(usex cython "" --no-cython)
+					  $(usex libev "" --no-libev)
+					  $(usex murmur "" --no-murmur3) )
+}
+
+python_compile_all() {
+	use doc && esetup.py doc
+}
+
+python_test() {
+	nosetests -v tests.unit || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all "${@}"
+	use doc && dohtml -r docs/_build/${PV}/.
+}
+
+pkg_postinst() {
+	einfo
+	einfo "Some behaviors of this driver are enabled at run-time"
+	einfo "when certain libs are detected.  Compression support is"
+	einfo "enabled if dev-python/lz4 or dev-python/snappy are"
+	einfo "installed.  Also scales (for metrics) and blist (for"
+	einfo "sorted sets) provide additional features, though there"
+	einfo "are not packages in the tree yet (install with pip)."
+	einfo
+}
+
+# TODO
+# - dev-python/eventlet and dev-python/gevent appear to be
+#   optional runtime deps but the docs never explicitly mention them.
+#   Is it maybe the case that one of the two is required, but only
+#   if libev is built?
diff --git a/dev-python/cassandra-driver/metadata.xml b/dev-python/cassandra-driver/metadata.xml
new file mode 100644
index 000000000000..74e61dd26877
--- /dev/null
+++ b/dev-python/cassandra-driver/metadata.xml
@@ -0,0 +1,27 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<herd>python</herd>
+	<maintainer>
+		<email>stasibear@gentoo.org</email>
+		<name>Erik Mackdanz</name>
+	</maintainer>
+	<longdescription>
+		A modern, feature-rich and highly-tunable Python
+		client library for Apache Cassandra (1.2+) and
+		DataStax Enterprise (3.1+) using exclusively
+		Cassandra's binary protocol and Cassandra Query
+		Language v3.
+	</longdescription>
+	<use>
+		<flag name="cython">
+			Optimize core modules and build custom extensions
+		</flag>
+		<flag name="libev">
+			libev event loop integration
+		</flag>
+		<flag name="murmur">
+			Faster hashing for token-aware routing
+		</flag>
+	</use>
+</pkgmetadata>