dev-python/keyring: Install missing files

Bug: https://github.com/jaraco/keyring/issues/621
Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 62 insertions, 0 deletions

diff --git a/dev-python/keyring/keyring-23.13.1-r1.ebuild b/dev-python/keyring/keyring-23.13.1-r1.ebuild
new file mode 100644
index 000000000000..fcef2b34ff55
--- /dev/null
+++ b/dev-python/keyring/keyring-23.13.1-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Provides access to the system keyring service"
+HOMEPAGE="
+	https://github.com/jaraco/keyring/
+	https://pypi.org/project/keyring/
+"
+SRC_URI="
+	https://github.com/jaraco/keyring/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+SLOT="0"
+LICENSE="PSF-2"
+KEYWORDS="amd64 arm arm64 ppc ppc64 ~riscv ~s390 sparc x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/secretstorage-3.2[${PYTHON_USEDEP}]
+	dev-python/jaraco-classes[${PYTHON_USEDEP}]
+	>=dev-python/jeepney-0.4.2[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_metadata-4.11.4[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10 3.11)
+	$(python_gen_cond_dep '
+		dev-python/importlib_resources
+	' 3.8)
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+EPYTEST_DESELECT=(
+	# this test fails if importlib-metadata returns more than one
+	# entry, i.e. when keyring is installed already
+	tests/test_packaging.py::test_entry_point
+)
+
+EPYTEST_IGNORE=(
+	# apparently does not unlock the keyring properly
+	tests/backends/test_libsecret.py
+	# hangs
+	tests/backends/test_kwallet.py
+)
+
+python_compile() {
+	distutils-r1_python_compile
+	# https://github.com/jaraco/keyring/issues/621
+	python_moduleinto keyring
+	python_domodule keyring/{py.typed,*.zsh}
+}