dev-python/pikepdf: Bump to 8.10.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 63 insertions, 0 deletions

diff --git a/dev-python/pikepdf/Manifest b/dev-python/pikepdf/Manifest
index 4a111f12e9f1..51287565648e 100644
--- a/dev-python/pikepdf/Manifest
+++ b/dev-python/pikepdf/Manifest
@@ -1,3 +1,4 @@
+DIST pikepdf-8.10.0.tar.gz 2865745 BLAKE2B 088b18c1ed5df942f5efc01d1895af6417a05bb2f5e249c2ad134f282456fe9841e8fd6414005f21845aabc9a543967b1c73f41b36e3c85821f656c1fa3c5275 SHA512 5e7ce6a0a8036e9387a0e94a67cacf5276ff9e0a08d70ed523ed6c2d0da3386ac16cc315dab490c492f3ea446fd85b2ff371fe3d3979a9efd3cc784b31f46c7d
 DIST pikepdf-8.4.1.tar.gz 2853305 BLAKE2B 2298514159db17ba49b8e2fa2407d60de50273bea111ece704251d99193bdc4c8ed77f624237a49c3f4f129e3b14ac4ddd1006cf3024bcbf822bc5523e0fee35 SHA512 6989e8a3888f612e453ec1ea8425c0ca35ccfee19ae5e8c32df136ebc3fbb7728d9fe5beaacb4e392a20c9037a1009fc8f8d53d73634427fb0df9103626e34fa
 DIST pikepdf-8.7.1.tar.gz 2860480 BLAKE2B fa06667947d0166e8597e4fa757ffa96eb69ed3fe2dfd4a54e515678f55afd15a0e2dfcd571fabc933423f0696725d623b0fb9f95cb8ca8633a6581a7957c25d SHA512 3adc075244eb66e0aa4b18882c2ede598b26a40c56497628a8262f82c8ec72af25b4c97ded0771a8e0ec7bb1e7537ec4e172505fd30271a995491361bf17277f
 DIST pikepdf-8.8.0.tar.gz 2865070 BLAKE2B 78c26c577db858c27a1aa632c0e93a955eafc76f3e5928a5d4862408a71c02b66325e51728e81a5d6bd571655b2c96468592b3c591993e4cf6ecfa28fd997a89 SHA512 91bdf67a800c18559172c7a253859e6e5ef443b0f6e2d2f3af21042db2640f9d96a8fb5764e6ddd64ace248788e32b071ed624c95a6a0557ba19dc6fc33fdf76
diff --git a/dev-python/pikepdf/pikepdf-8.10.0.ebuild b/dev-python/pikepdf/pikepdf-8.10.0.ebuild
new file mode 100644
index 000000000000..670325f6bba5
--- /dev/null
+++ b/dev-python/pikepdf/pikepdf-8.10.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python library to work with pdf files based on qpdf"
+HOMEPAGE="
+	https://github.com/pikepdf/pikepdf/
+	https://pypi.org/project/pikepdf/
+"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# Check QPDF_MIN_VERSION in pyproject.toml on bumps, as well as
+# https://qpdf.readthedocs.io/en/stable/release-notes.html.
+DEPEND="
+	>=app-text/qpdf-11.5.0:0=
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/deprecated[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pillow-10.0.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pybind11-2.10.1[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-scm-7.0.5[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/attrs-20.2.0[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-6.36[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.21.0[${PYTHON_USEDEP}]
+		>=dev-python/pillow-5.0.0[${PYTHON_USEDEP},jpeg,lcms,tiff]
+		>=dev-python/psutil-5.9[${PYTHON_USEDEP}]
+		>=dev-python/pytest-timeout-2.1.0[${PYTHON_USEDEP}]
+		>=dev-python/python-dateutil-2.8.1[${PYTHON_USEDEP}]
+		>=dev-python/python-xmp-toolkit-2.0.1[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/tomli[${PYTHON_USEDEP}]
+		' 3.10)
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# fragile to system load
+	tests/test_image_access.py::test_random_image
+)
+
+src_prepare() {
+	sed -e '/-n auto/d' -i pyproject.toml || die
+	distutils-r1_src_prepare
+}