dev-python/poetry: Bump to 2.0.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 86 insertions, 0 deletions

diff --git a/dev-python/poetry/Manifest b/dev-python/poetry/Manifest
index d9e75eb98529..dcb2da62554d 100644
--- a/dev-python/poetry/Manifest
+++ b/dev-python/poetry/Manifest
@@ -1 +1,2 @@
 DIST poetry-1.8.5.tar.gz 1519790 BLAKE2B 378cb327fe6762e8dd09d7f08fb11cd17963c382754a20fba3cc000ac07ab93672b54d967ba6d609d00e9f303461e55ec40eb9549a0b9329f50c4af363fd2343 SHA512 91c2902e5dfb8f3319de53472b1da20b1d8f570a7a3212e6e55883e364295a9e58ce5b7c59450e741f97692e897283d9f624f3d2128db017476d94fd2ea7839c
+DIST poetry-2.0.0.tar.gz 2844621 BLAKE2B 17c3c91c839e3a7bd5f27b7659cd4906bfc5337d64699d92614bd880f1c9351ab2dd05d8486ce7304860b1705c0f6e16526f10e2f7f71ec2ad5234807fca3327 SHA512 82ecf902dfa804ff54f4d77557d51d781f29a532699d3d901a844c9ed5906d421869d90789468d563febaa838ad6b237c0021eb4b27953233e351929ca556c1d
diff --git a/dev-python/poetry/poetry-2.0.0.ebuild b/dev-python/poetry/poetry-2.0.0.ebuild
new file mode 100644
index 000000000000..aa856184ffdd
--- /dev/null
+++ b/dev-python/poetry/poetry-2.0.0.ebuild
@@ -0,0 +1,85 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A frontend for poetry - a python dependency management and packaging tool"
+HOMEPAGE="
+	https://python-poetry.org/
+	https://github.com/python-poetry/poetry
+	https://pypi.org/project/poetry/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/poetry-core-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/poetry-plugin-export-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/build-1.2.1[${PYTHON_USEDEP}]
+	>=dev-python/cachecontrol-0.14.0[${PYTHON_USEDEP}]
+	>=dev-python/cleo-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/dulwich-0.22.6[${PYTHON_USEDEP}]
+	>=dev-python/fastjsonschema-2.18.0[${PYTHON_USEDEP}]
+	>=dev-python/installer-0.7.0[${PYTHON_USEDEP}]
+	>=dev-python/keyring-25.1.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-24.0[${PYTHON_USEDEP}]
+	>=dev-python/pkginfo-1.12[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.26[${PYTHON_USEDEP}]
+	>=dev-python/requests-toolbelt-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/shellingham-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/tomlkit-0.11.6[${PYTHON_USEDEP}]
+	>=dev-python/trove-classifiers-2022.5.19[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.26.0[${PYTHON_USEDEP}]
+	>=dev-python/virtualenv-20.26.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.10)
+"
+
+BDEPEND="
+	test? (
+		>=dev-python/deepdiff-6.3.1[${PYTHON_USEDEP}]
+		>=dev-python/httpretty-1.1[${PYTHON_USEDEP}]
+		>=dev-python/jaraco-classes-3.3.1[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-3.9[${PYTHON_USEDEP}]
+	)
+"
+
+src_prepare() {
+	# unpin
+	sed -e 's:\^:>=:' \
+		-e '/poetry-core/s:":">=:' \
+		-e 's:,<[0-9.]*::' \
+		-i pyproject.toml || die
+
+	distutils-r1_src_prepare
+}
+
+EPYTEST_DESELECT=(
+	# Internal test for lockfile being up-to-date
+	# Meaningless, also sdist does not include lockfile
+	tests/installation/test_installer.py::test_not_fresh_lock
+
+	# TODO
+	tests/installation/test_executor.py::test_executor_known_hashes
+	tests/puzzle/test_provider.py::test_search_for_directory_setup_read_setup_with_no_dependencies
+	tests/utils/env/test_env_manager.py::test_create_venv_finds_no_python_executable
+	tests/utils/test_python_manager.py::test_python_get_preferred_default
+	'tests/inspection/test_info.py::test_info_setup_missing_mandatory_should_trigger_pep517[name]'
+)
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -m "not network" -p pytest_mock
+}