dev-python/pytables: Bump to 3.6.1

Closes: https://bugs.gentoo.org/663960
Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

2 files changed, 80 insertions, 0 deletions

diff --git a/dev-python/pytables/Manifest b/dev-python/pytables/Manifest
index 5c874c962882..995b04c680a8 100644
--- a/dev-python/pytables/Manifest
+++ b/dev-python/pytables/Manifest
@@ -1 +1,2 @@
 DIST tables-3.4.4.tar.gz 4626053 BLAKE2B cca4f87aa62db16bb47e131bf670e1013d363dea9c807f399688e184610f682c49b00b686d8e28a03caf94a98e51b11bf646df66f4e3db66f481751f096906f8 SHA512 2d0cdd36a6f14702f424773b64187d1980d73a72525ead43b272776bb32b2ebc4c6ea0b7e3343c8600d7f62c42d008b5e835439af30e76ea11c7504666631ddf
+DIST tables-3.6.1.tar.gz 4641089 BLAKE2B 4ef44b1263f40babe6719bac911ab191e9cb0c58c377705b755fa83f1fba5af1d0fab10b0b45bd6af619a9dce4842a80afad8d8fbab64c3be4f35a1b3f117ee3 SHA512 7f018b70251095049bce9075be4e19f72efba9d39121a35c4521f634b1dd5b81ab6de47df3bb44ad6b8b2dbdbff4e6d0985ad1a7b2f13b44f920c0935e5830ff
diff --git a/dev-python/pytables/pytables-3.6.1.ebuild b/dev-python/pytables/pytables-3.6.1.ebuild
new file mode 100644
index 000000000000..abe2b97d2fe5
--- /dev/null
+++ b/dev-python/pytables/pytables-3.6.1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{6..9} )
+PYTHON_REQ_USE="threads(+)"
+
+MY_PN=tables
+MY_P=${MY_PN}-${PV}
+
+inherit distutils-r1 flag-o-matic
+
+DESCRIPTION="Hierarchical datasets for Python"
+HOMEPAGE="https://www.pytables.org/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+LICENSE="BSD"
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-arch/bzip2:0=
+	app-arch/lz4:0=
+	>=app-arch/zstd-1.0.0:=
+	>=dev-libs/c-blosc-1.11.1:0=
+	dev-libs/lzo:2=
+	>=dev-python/numpy-1.8.1[${PYTHON_USEDEP}]
+	>=dev-python/numexpr-2.5.2[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	>=sci-libs/hdf5-1.8.15:0=
+"
+DEPEND="${RDEPEND}
+	>=dev-python/cython-0.21[${PYTHON_USEDEP}]
+	test? ( dev-python/mock[${PYTHON_USEDEP}] )
+"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( RELEASE_NOTES.txt THANKS )
+
+python_prepare_all() {
+	export HDF5_DIR="${EPREFIX}"/usr
+	rm tables/*.c || die
+	sed -e "s:/usr:${EPREFIX}/usr:g" \
+		-i setup.py || die
+	rm -r c-blosc/{blosc,internal-complibs} || die
+	sed -i -e '/_version/ s/\\s\*/\\s\+/' setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	if ! python_is_python3; then
+		local -x CFLAGS="${CFLAGS}"
+		append-cflags -fno-strict-aliasing
+	fi
+	distutils-r1_python_compile
+}
+
+python_test() {
+	cd "${BUILD_DIR}"/lib* || die
+	${EPYTHON} tables/tests/test_all.py || die
+}
+
+python_install_all() {
+	if use doc; then
+		DOCS+=( doc/scripts )
+	fi
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		dodoc -r contrib
+		docompress -x /usr/share/doc/${PF}/examples
+		docompress -x /usr/share/doc/${PF}/contrib
+	fi
+}