dev-python/zope-schema: add 6.2.1

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

1 files changed, 54 insertions, 0 deletions

diff --git a/dev-python/zope-schema/zope-schema-6.2.1.ebuild b/dev-python/zope-schema/zope-schema-6.2.1.ebuild
new file mode 100644
index 000000000000..8157f0091af8
--- /dev/null
+++ b/dev-python/zope-schema/zope-schema-6.2.1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+
+inherit distutils-r1
+
+MY_PN=${PN/-/.}
+MY_P=${MY_PN}-${PV}
+DESCRIPTION="Zope schema Architecture"
+HOMEPAGE="
+	https://pypi.org/project/zope.schema/
+	https://github.com/zopefoundation/zope.schema/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/zope-event[${PYTHON_USEDEP}]
+	>=dev-python/zope-interface-5.0.0[${PYTHON_USEDEP}]
+	!dev-python/namespace-zope
+"
+BDEPEND="
+	test? (
+		dev-python/zope-i18nmessageid[${PYTHON_USEDEP}]
+		dev-python/zope-testing[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# strip rdep specific to namespaces
+	sed -i -e "/'setuptools'/d" setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	distutils_write_namespace zope
+	eunittest
+}