dev-python/cython: Remove old

Signed-off-by: Michał Górny <mgorny@gentoo.org>

3 files changed, 0 insertions, 166 deletions

diff --git a/dev-python/cython/Manifest b/dev-python/cython/Manifest
index d259e75b16fa..9bb8e6d68aa3 100644
--- a/dev-python/cython/Manifest
+++ b/dev-python/cython/Manifest
@@ -1,4 +1,2 @@
-DIST cython-0.29.32.gh.tar.gz 2110417 BLAKE2B 008ffe325c87d165bf45afb2ff92db5286f611bbe425d0e9f18b530202135ca21f5f5ab564a4d0c6251ec2479ea0fd19207274a255fb1faf8863d3b067d17ae9 SHA512 55462792fa70d8edf60aa470627ab494918d7297fd7d282a7a54da76ee5a180233108404a1c8f3d79f6408f19b6e4f46b36e59fd47c38ede24f061f374437b6f
 DIST cython-0.29.33.gh.tar.gz 2113910 BLAKE2B 9212edfa36680a3243632d28c4f5616a7336e82ee1f96df7d5e29711056619639c9a8fe9bbf9aea0a86aed39e836dc6eaa112ad35080f530add6309ccd09c53c SHA512 85f5ba7159d8793dbda980140b26086727f356a71d78f8522419657841d07b865d09c2f0a0f77d398669d071c1d261060235321a19eb7808e35d24f8ac71560d
-DIST cython-3.0.0b1.gh.tar.gz 2659132 BLAKE2B 7ed252d90f71521f24817e064f1b55f671185053cdd46214fb14f2b6e16dbfbc46e87659681ead40a32bb0506150ae6b8cdbaceae7667811aa81f97a39b5efcc SHA512 a7b2e9c22d19eab9e4ad551895e5c8882a7098a52865e341fd84d902124b4599d193d202333d9f1ffd5354fff62637c65d124820e6721905edaed46b5881b14c
 DIST cython-3.0.0b2.gh.tar.gz 2669448 BLAKE2B 87602a43f77f8005adfc71ec0598a12212db917071dd2ae9a7d0d909411e38525290d860a8606600a5e1b07b014da65d2398f04818837fb15f66bcdba0cad965 SHA512 2095a556bc83669a89902a71da2164fbfab2b75cec2de95c91f95b6b3639bc5802b09808059896ed564b0d6e0539e497051614572bc8ba5d678d0410ccc3914f
diff --git a/dev-python/cython/cython-0.29.32.ebuild b/dev-python/cython/cython-0.29.32.ebuild
deleted file mode 100644
index d22db93be6c9..000000000000
--- a/dev-python/cython/cython-0.29.32.ebuild
+++ /dev/null
@@ -1,90 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{9..11} pypy3 )
-PYTHON_REQ_USE="threads(+)"
-
-inherit distutils-r1 toolchain-funcs elisp-common
-
-DESCRIPTION="A Python to C compiler"
-HOMEPAGE="
-	https://cython.org/
-	https://github.com/cython/cython/
-	https://pypi.org/project/Cython/
-"
-SRC_URI="
-	https://github.com/cython/cython/archive/${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris ~x86-solaris"
-IUSE="emacs test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	emacs? ( >=app-editors/emacs-23.1:* )
-"
-BDEPEND="
-	${RDEPEND}
-	test? (
-		$(python_gen_cond_dep '
-			dev-python/numpy[${PYTHON_USEDEP}]
-		' python3_{8..10})
-	)
-"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-0.29.22-spawn-multiprocessing.patch"
-	"${FILESDIR}/${PN}-0.29.23-test_exceptions-py310.patch"
-)
-
-SITEFILE=50cython-gentoo.el
-
-distutils_enable_sphinx docs
-
-python_compile() {
-	# Python gets confused when it is in sys.path before build.
-	local -x PYTHONPATH=
-
-	distutils-r1_python_compile
-}
-
-python_compile_all() {
-	use emacs && elisp-compile Tools/cython-mode.el
-}
-
-python_test() {
-	if has "${EPYTHON}" pypy3 python3.11; then
-		einfo "Skipping tests on ${EPYTHON} (xfail)"
-		return
-	fi
-
-	tc-export CC
-	# https://github.com/cython/cython/issues/1911
-	local -x CFLAGS="${CFLAGS} -fno-strict-overflow"
-	"${PYTHON}" runtests.py -vv --work-dir "${BUILD_DIR}"/tests ||
-		die "Tests fail with ${EPYTHON}"
-}
-
-python_install_all() {
-	local DOCS=( CHANGES.rst README.rst ToDo.txt USAGE.txt )
-	distutils-r1_python_install_all
-
-	if use emacs; then
-		elisp-install ${PN} Tools/cython-mode.*
-		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
-	fi
-}
-
-pkg_postinst() {
-	use emacs && elisp-site-regen
-}
-
-pkg_postrm() {
-	use emacs && elisp-site-regen
-}
diff --git a/dev-python/cython/cython-3.0.0_beta1-r2.ebuild b/dev-python/cython/cython-3.0.0_beta1-r2.ebuild
deleted file mode 100644
index 3765013cc291..000000000000
--- a/dev-python/cython/cython-3.0.0_beta1-r2.ebuild
+++ /dev/null
@@ -1,74 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{9..11} pypy3 )
-PYTHON_REQ_USE="threads(+)"
-
-inherit distutils-r1 toolchain-funcs elisp-common
-
-MY_P=${P/_beta/b}
-DESCRIPTION="A Python to C compiler"
-HOMEPAGE="
-	https://cython.org/
-	https://github.com/cython/cython/
-	https://pypi.org/project/Cython/
-"
-SRC_URI="
-	https://github.com/cython/cython/archive/${PV/_beta/b}.tar.gz
-		-> ${MY_P}.gh.tar.gz
-"
-S=${WORKDIR}/${MY_P}
-
-LICENSE="Apache-2.0"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris ~x86-solaris"
-IUSE="test"
-RESTRICT="!test? ( test )"
-
-BDEPEND="
-	${RDEPEND}
-	test? (
-		$(python_gen_cond_dep '
-			dev-python/numpy[${PYTHON_USEDEP}]
-		' python3_{8..10})
-	)
-"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-0.29.22-spawn-multiprocessing.patch"
-	"${FILESDIR}/${PN}-0.29.23-test_exceptions-py310.patch"
-	"${FILESDIR}/${PN}-0.29.23-pythran-parallel-install.patch"
-)
-
-distutils_enable_sphinx docs \
-	dev-python/jinja \
-	dev-python/sphinx-issues \
-	dev-python/sphinx-tabs
-
-python_compile() {
-	# Python gets confused when it is in sys.path before build.
-	local -x PYTHONPATH=
-
-	distutils-r1_python_compile
-}
-
-python_test() {
-	if has "${EPYTHON}" pypy3 python3.11; then
-		einfo "Skipping tests on ${EPYTHON} (xfail)"
-		return
-	fi
-
-	tc-export CC
-	# https://github.com/cython/cython/issues/1911
-	local -x CFLAGS="${CFLAGS} -fno-strict-overflow"
-	"${PYTHON}" runtests.py -vv --work-dir "${BUILD_DIR}"/tests ||
-		die "Tests fail with ${EPYTHON}"
-}
-
-python_install_all() {
-	local DOCS=( CHANGES.rst README.rst ToDo.txt USAGE.txt )
-	distutils-r1_python_install_all
-}