dev-ruby/ruby-xslt: fix compatability with libxslt 1.30, bug 631244

Package-Manager: Portage-2.3.8, Repoman-2.3.2

1 files changed, 49 insertions, 0 deletions

diff --git a/dev-ruby/ruby-xslt/ruby-xslt-0.9.9-r4.ebuild b/dev-ruby/ruby-xslt/ruby-xslt-0.9.9-r4.ebuild
new file mode 100644
index 000000000000..5f0c6c23f96d
--- /dev/null
+++ b/dev-ruby/ruby-xslt/ruby-xslt-0.9.9-r4.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+USE_RUBY="ruby21 ruby22 ruby23 ruby24"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_TASK_TEST=""
+
+RUBY_FAKEGEM_EXTRADOC="ChangeLog.rdoc AUTHORS.rdoc README.rdoc"
+
+inherit multilib ruby-fakegem
+
+DESCRIPTION="A Ruby class for processing XSLT"
+HOMEPAGE="http://www.rubyfr.net/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND+=" >=dev-libs/libxslt-1.1.12"
+RDEPEND+=" >=dev-libs/libxslt-1.1.12"
+
+all_ruby_prepare() {
+	# Remove forced -g compiler flag.
+	sed -i -e 's/-g //' ext/xslt_lib/extconf.rb || die
+
+	# One test fails but we have installed this code already for a long
+	# time so this probably isn't a regression. No upstream bug tracker
+	# to report the problem :-(
+	sed -i -e '/test_transformation_error/,/^  end/ s:^:#:' test/test.rb || die
+
+	# Fix compatability with libxslt 1.30
+	sed -i -e '/XSLT_NORM_SAXON_NAMESPACE/d' ext/xslt_lib/xslt_lib.c || die
+}
+
+each_ruby_configure() {
+	${RUBY} -C ext/xslt_lib extconf.rb || die
+}
+
+each_ruby_compile() {
+	emake -C ext/xslt_lib V=1
+	cp ext/xslt_lib/xslt_lib$(get_modname) lib/xml/ || die
+}
+
+each_ruby_test() {
+	${RUBY} -I../lib:lib -Ctest test.rb || die
+}