dev-util/azuredatastudio: bump to 1.49.0

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

2 files changed, 106 insertions, 0 deletions

diff --git a/dev-util/azuredatastudio/Manifest b/dev-util/azuredatastudio/Manifest
index 3a8de8ba13d8..1a75b6ab51b5 100644
--- a/dev-util/azuredatastudio/Manifest
+++ b/dev-util/azuredatastudio/Manifest
@@ -1 +1,2 @@
 DIST azuredatastudio-1.48.1-amd64.deb 135147824 BLAKE2B 91beda52e72ec24c40d7502756396145117d17f7d4c7fa440c1ea03b84e782a6d966189b4db946b710400624d3bd91a9a30158b3fb59f3043c82062bd326c492 SHA512 dd76c9d670a09c440805f3bf5a66b424fb7e1f1e32643ed65852dd47771c0c310881df98a37801012e85deed82a34c42c69105a055306c6f33eb764ec1da88d4
+DIST azuredatastudio-1.49.0-amd64.deb 135147824 BLAKE2B 91beda52e72ec24c40d7502756396145117d17f7d4c7fa440c1ea03b84e782a6d966189b4db946b710400624d3bd91a9a30158b3fb59f3043c82062bd326c492 SHA512 dd76c9d670a09c440805f3bf5a66b424fb7e1f1e32643ed65852dd47771c0c310881df98a37801012e85deed82a34c42c69105a055306c6f33eb764ec1da88d4
diff --git a/dev-util/azuredatastudio/azuredatastudio-1.49.0.ebuild b/dev-util/azuredatastudio/azuredatastudio-1.49.0.ebuild
new file mode 100644
index 000000000000..d8d032ceea34
--- /dev/null
+++ b/dev-util/azuredatastudio/azuredatastudio-1.49.0.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit unpacker xdg
+
+DESCRIPTION="Data management and development tool from Microsoft"
+HOMEPAGE="https://learn.microsoft.com/sql/azure-data-studio/
+	https://github.com/microsoft/azuredatastudio/"
+SRC_URI="
+	amd64? (
+		https://azuredatastudio-update.azurewebsites.net/${PV}/linux-deb-x64/stable
+			-> ${P}-amd64.deb
+	)
+"
+S="${WORKDIR}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+IUSE="kerberos"
+RESTRICT="bindist"
+
+# This is based on VSCode/VSCodium, so just copy their "RDEPEND".
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	app-crypt/libsecret[crypt]
+	app-misc/ca-certificates
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	dev-util/lttng-ust:0/2.12
+	media-libs/alsa-lib
+	media-libs/libcanberra[gtk3]
+	media-libs/libglvnd
+	media-libs/mesa
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/zlib
+	sys-process/lsof
+	x11-libs/cairo
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libnotify
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libxkbcommon
+	x11-libs/libxkbfile
+	x11-libs/libXrandr
+	x11-libs/libXScrnSaver
+	x11-libs/pango
+	x11-misc/xdg-utils
+	kerberos? ( app-crypt/mit-krb5 )
+"
+DEPEND="
+	dev-libs/openssl-compat:1.0.0
+"
+BDEPEND="
+	dev-util/patchelf
+"
+
+QA_PREBUILT="*"
+
+src_unpack() {
+	unpack_deb "${A}"
+}
+
+src_prepare() {
+	default
+
+	cd "${S}/usr/share" || die
+
+	mv appdata metainfo || die
+	mv zsh/vendor-completions zsh/site-functions || die
+
+	cd "${PN}" || die
+
+	# Kerberos libs, same issue as VSCode/VSCodium.
+	if ! use kerberos ; then
+		rm -r resources/app/node_modules.asar.unpacked/kerberos || die
+	fi
+
+	# Patch "System.Security.Cryptography.Native.OpenSsl.so": *.so.10 -> *.so.1.0.0
+	local mssql_ext_version=4.11.1.1
+	local mssql_ext_lib=System.Security.Cryptography.Native.OpenSsl.so
+	cd "resources/app/extensions/mssql/sqltoolsservice/Linux/${mssql_ext_version}" || die
+	patchelf --add-needed libcrypto.so.1.0.0 "${mssql_ext_lib}" || die
+	patchelf --add-needed libssl.so.1.0.0 "${mssql_ext_lib}" || die
+	patchelf --remove-needed libcrypto.so.10 "${mssql_ext_lib}" || die
+	patchelf --remove-needed libssl.so.10 "${mssql_ext_lib}" || die
+	rm System.Native.a || die
+}
+
+src_install() {
+	cp -r . "${ED}" || die
+
+	dosym -r "/usr/share/${PN}/${PN}" "/usr/bin/${PN}"
+}