dev-util/vulkan-tools: add 1.3.296.0

Signed-off-by: Nick Sarnie <sarnex@gentoo.org>

2 files changed, 86 insertions, 0 deletions

diff --git a/dev-util/vulkan-tools/Manifest b/dev-util/vulkan-tools/Manifest
index 24636562ff37..46334006003a 100644
--- a/dev-util/vulkan-tools/Manifest
+++ b/dev-util/vulkan-tools/Manifest
@@ -1 +1,2 @@
 DIST vulkan-tools-1.3.290.0.tar.gz 754806 BLAKE2B 322763f930660b52ac1fd4b56f5b7cd133b49da7a5ecf4f6d36712029dfba44edaa61ab65eaf4f9771ec5e5fac159e8d30b46b0f057b3d9b61220e58dab07ff8 SHA512 e5f6daa12ba2e8098f939cc06e732efd89f616fd9babf00d2fb8b9a73671143961a4c5b84879a4f9c4a7312bb393874f065222602e3619db5ad7fb9f8b868422
+DIST vulkan-tools-1.3.296.0.tar.gz 757355 BLAKE2B b5fa5ad2cc1aacd1f31361a85eb4df95701c7dd0207092722941ace9d5b215c1a094982f3713b3a8e77dc4ffb46e0cbbf7957bdf7ff089d2174e697dafdd9a0b SHA512 66bc89272f150198cd52f2971ad67a2fd6c922ac4bafb420c0d54788ca6bab2246e8a153a09eccce15a87e1fe16fdeef16af1c6b6b13386bff79dd73858f3cae
diff --git a/dev-util/vulkan-tools/vulkan-tools-1.3.296.0.ebuild b/dev-util/vulkan-tools/vulkan-tools-1.3.296.0.ebuild
new file mode 100644
index 000000000000..1c19288ef980
--- /dev/null
+++ b/dev-util/vulkan-tools/vulkan-tools-1.3.296.0.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN=Vulkan-Tools
+PYTHON_COMPAT=( python3_{10..13} )
+inherit cmake-multilib python-any-r1
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
+	EGIT_SUBMODULES=()
+	inherit git-r3
+else
+	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/vulkan-sdk-${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv"
+	S="${WORKDIR}"/${MY_PN}-vulkan-sdk-${PV}
+fi
+
+DESCRIPTION="Official Vulkan Tools and Utilities for Windows, Linux, Android, and MacOS"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-Tools"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="cube wayland X"
+
+BDEPEND="${PYTHON_DEPS}
+	cube? ( ~dev-util/glslang-${PV}:=[${MULTILIB_USEDEP}] )
+"
+RDEPEND="
+	~dev-util/volk-${PV}:=[${MULTILIB_USEDEP}]
+	~media-libs/vulkan-loader-${PV}[${MULTILIB_USEDEP},wayland?,X?]
+	wayland? ( dev-libs/wayland[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11[${MULTILIB_USEDEP}]
+		x11-libs/libxcb:=[${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}
+	~dev-util/vulkan-headers-${PV}
+	X? ( x11-libs/libXrandr[${MULTILIB_USEDEP}] )
+"
+
+pkg_setup() {
+	MULTILIB_CHOST_TOOLS=(
+		/usr/bin/vulkaninfo
+	)
+
+	use cube && MULTILIB_CHOST_TOOLS+=(
+		/usr/bin/vkcube
+		/usr/bin/vkcubepp
+	)
+	use cube && use wayland && MULTILIB_CHOST_TOOLS+=(
+		/usr/bin/vkcube-wayland
+	)
+
+	python-any-r1_pkg_setup
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_C_FLAGS="${CFLAGS} -DNDEBUG"
+		-DCMAKE_CXX_FLAGS="${CXXFLAGS} -DNDEBUG"
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_VULKANINFO=ON
+		-DBUILD_CUBE=$(usex cube)
+		-DBUILD_WERROR=OFF
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DVULKAN_HEADERS_INSTALL_DIR="${ESYSROOT}/usr"
+	)
+
+	if use cube; then
+		if use X; then
+			mycmakeargs+=(-DCUBE_WSI_SELECTION=XCB)
+		elif use wayland; then
+			mycmakeargs+=(-DCUBE_WSI_SELECTION=WAYLAND)
+		else
+			mycmakeargs+=(-DCUBE_WSI_SELECTION=DISPLAY)
+		fi
+	fi
+
+	cmake_src_configure
+}