proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 71 insertions, 0 deletions

diff --git a/games-roguelike/moria/moria-5.5.2.ebuild b/games-roguelike/moria/moria-5.5.2.ebuild
new file mode 100644
index 000000000000..e1994f5f6905
--- /dev/null
+++ b/games-roguelike/moria/moria-5.5.2.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils toolchain-funcs games
+
+DESCRIPTION="Rogue-like D&D curses game similar to nethack (BUT BETTER)"
+HOMEPAGE="http://remarque.org/~grabiner/moria.html"
+SRC_URI="ftp://ftp.greyhelm.com/pub/Games/Moria/source/um${PV}.tar.Z
+	http://www.funet.fi/pub/unix/games/moria/source/um${PV}.tar.Z
+	http://www.piratehaven.org/~beej/moria/mirror/Games/Moria/source/um${PV}.tar.Z
+	http://alge.anart.no/ftp/pub/games/RPG/moria/um${PV}.tar.Z
+	ftp://kane.evendata.net/pub/${PN}-extras.tar.bz2"
+
+LICENSE="Moria"
+SLOT="0"
+KEYWORDS="amd64 ppc x86 ~x86-fbsd"
+IUSE=""
+
+RDEPEND=">=sys-libs/ncurses-5"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+S=${WORKDIR}/umoria
+
+src_prepare() {
+	local f
+
+	epatch \
+		"${FILESDIR}"/${PV}-gentoo-paths.patch \
+		"${FILESDIR}"/${PV}-glibc.patch \
+		"${FILESDIR}"/${PV}-fbsd.patch \
+		"${FILESDIR}"/${PV}-hours.patch \
+		"${FILESDIR}"/${PV}-warnings.patch
+
+	for f in source/* unix/* ; do
+		ln -s ${f} $(basename ${f})
+	done
+
+	sed -i \
+		-e "s:David Grabiner:root:" \
+		-e "s:GENTOO_DATADIR:${GAMES_DATADIR}/${PN}:" \
+		-e "s:GENTOO_STATEDIR:${GAMES_STATEDIR}:" \
+		config.h || die
+	{
+		echo "#include <stdlib.h>"
+		echo "#include <stdio.h>"
+	} >> config.h || die
+	sed -i \
+		-e "/^STATEDIR =/s:=.*:=\$(DESTDIR)${GAMES_STATEDIR}:" \
+		-e "/^BINDIR = /s:=.*:=\$(DESTDIR)${GAMES_BINDIR}:" \
+		-e "/^LIBDIR = /s:=.*:=\$(DESTDIR)${GAMES_DATADIR}/${PN}:" \
+		-e "/^CFLAGS = /s:=.*:=${CFLAGS}:" \
+		-e "/^OWNER = /s:=.*:=${GAMES_USER}:" \
+		-e "/^GROUP = /s:=.*:=${GAMES_GROUP}:" \
+		-e "/^CC = /s:=.*:=$(tc-getCC):" \
+		-e '/^LFLAGS = /s:=.*:= $(LDFLAGS):' \
+		Makefile || die
+	mv doc/moria.6 "${S}" || die
+}
+
+src_install() {
+	dodir "${GAMES_BINDIR}" "${GAMES_DATADIR}/${PN}" "${GAMES_STATEDIR}"
+	emake DESTDIR="${D}" install
+
+	doman moria.6
+	dodoc README doc/* "${WORKDIR}"/${PN}-extras/*
+
+	prepgamesdirs
+}