gnome-base/gnome-settings-daemon: Version bump to 42.2

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 149 insertions, 0 deletions

diff --git a/gnome-base/gnome-settings-daemon/Manifest b/gnome-base/gnome-settings-daemon/Manifest
index c545669a2f9c..bb99abbbe20c 100644
--- a/gnome-base/gnome-settings-daemon/Manifest
+++ b/gnome-base/gnome-settings-daemon/Manifest
@@ -1 +1,2 @@
 DIST gnome-settings-daemon-42.1.tar.xz 1481432 BLAKE2B d045b2e2a17c6c54f0014db03e1b2d645086d907383b849de82f972af39463acf06ab1207817f171fd3b7a33b60303d058f04495158bb49aab7899da740f732c SHA512 20e87fc2318d77af016ec071cc6070f43ac42eaaf60a1f9bdb4278f59e038268e0a37759f0ab31068d8701b9dc64d142c0a875f0eeaa700ad47e0dbca3b9d141
+DIST gnome-settings-daemon-42.2.tar.xz 1483864 BLAKE2B c2051f129e66df8ca55eb72b0c3a037275c89d3c519fe01822aa4ad2309af9a27e840f4f797a8ecac8e0767d8e7894ffe9c5942840b0ca57536325e3cbe12617 SHA512 66f1e766a7d1c36d4609c9505ba5d99516505ecfc5123483a3cbc6189d21cce23abf26da067bf9c05c3c25bc96d4568a8b07477f0722b0cb9442085f6d886e5c
diff --git a/gnome-base/gnome-settings-daemon/gnome-settings-daemon-42.2.ebuild b/gnome-base/gnome-settings-daemon/gnome-settings-daemon-42.2.ebuild
new file mode 100644
index 000000000000..0f6d9e6e2e82
--- /dev/null
+++ b/gnome-base/gnome-settings-daemon/gnome-settings-daemon-42.2.ebuild
@@ -0,0 +1,148 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit gnome.org gnome2-utils python-any-r1 meson udev virtualx xdg
+
+DESCRIPTION="Gnome Settings Daemon"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-settings-daemon"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+IUSE="+colord +cups debug elogind input_devices_wacom modemmanager networkmanager smartcard systemd test +udev wayland"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	^^ ( elogind systemd )
+	input_devices_wacom? ( udev )
+	wayland? ( udev )
+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+DEPEND="
+	>=sci-geosciences/geocode-glib-3.10
+	>=dev-libs/glib-2.58:2
+	>=gnome-base/gnome-desktop-3.37.1:3=
+	>=gnome-base/gsettings-desktop-schemas-42
+	>=x11-libs/gtk+-3.15.3:3[X,wayland?]
+	>=dev-libs/libgweather-4.0.0:4=
+	colord? (
+		>=x11-misc/colord-1.4.5:=
+		>=media-libs/lcms-2.2:2
+	)
+	media-libs/libcanberra[gtk3]
+	>=app-misc/geoclue-2.3.1:2.0
+	>=x11-libs/libnotify-0.7.3
+	>=media-sound/pulseaudio-12.99.3[glib]
+	>=sys-auth/polkit-0.114
+	>=sys-power/upower-0.99.12:=
+	x11-libs/libX11
+	>=x11-libs/libXfixes-6.0.0
+	udev? ( dev-libs/libgudev:= )
+	wayland? ( dev-libs/wayland )
+	input_devices_wacom? (
+		>=dev-libs/libwacom-0.7
+		>=x11-libs/pango-1.20.0
+		x11-libs/gdk-pixbuf:2
+	)
+	smartcard? ( >=dev-libs/nss-3.11.2 )
+	cups? ( >=net-print/cups-1.4[dbus] )
+	modemmanager? (
+		>=app-crypt/gcr-3.7.5:=
+		>=net-misc/modemmanager-1.0:=
+	)
+	networkmanager? ( >=net-misc/networkmanager-1.0 )
+	media-libs/alsa-lib
+	x11-libs/libXi
+	x11-libs/libXext
+	media-libs/fontconfig
+	systemd? (
+		>=sys-apps/systemd-243
+	)
+"
+# logind needed for power and session management, bug #464944
+# gnome-session-3.33.90/gdm-3.33.90/gnome-shell-extensions-3.34.1/gnome-flashback-3.33.1 adapt to Clipboard and Mouse component removals (moved to mutter)
+RDEPEND="${DEPEND}
+	gnome-base/dconf
+	elogind? ( sys-auth/elogind )
+	!<gnome-base/gnome-session-3.33.90
+	!<gnome-base/gdm-3.33.90
+	!<gnome-extra/gnome-shell-extensions-3.34.1
+	!<gnome-base/gnome-flashback-3.33.1
+"
+# rfkill requires linux/rfkill.h (and USE=udev), thus linux-headers dep, not os-headers. If this package wants to work on other kernels, we need to make rfkill conditional instead
+BDEPEND="
+	sys-kernel/linux-headers
+	dev-util/glib-utils
+	dev-util/gdbus-codegen
+	x11-base/xorg-proto
+	${PYTHON_DEPS}
+	test? (
+		$(python_gen_any_dep '
+			dev-python/pygobject:3[${PYTHON_USEDEP}]
+			dev-python/python-dbusmock[${PYTHON_USEDEP}]
+		')
+		gnome-base/gnome-session
+	)
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/42.1-build-Make-wacom-optional-and-controllable-via-meson.patch
+	"${FILESDIR}"/${PN}-3.38.1-build-Allow-NM-optional-on-Linux.patch
+	"${FILESDIR}"/${PN}-3.38.1-Allow-udev-optional-on-Linux.patch
+)
+
+python_check_deps() {
+	if use test; then
+		has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]" &&
+		has_version "dev-python/python-dbusmock[${PYTHON_USEDEP}]"
+	fi
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		#-Dnssdb_dir # TODO: Is the default /etc/pki/nssdb path correct for our nss?
+		-Dudev_dir="$(get_udevdir)"
+		$(meson_use systemd)
+		-Dalsa=true
+		$(meson_use udev gudev)
+		$(meson_use colord)
+		$(meson_use cups)
+		$(meson_use networkmanager network_manager)
+		$(meson_use udev rfkill)
+		$(meson_use smartcard)
+		$(meson_use input_devices_wacom wacom)
+		$(meson_use wayland)
+		$(meson_use modemmanager wwan)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	# Don't auto-suspend by default on AC power
+	insinto /usr/share/glib-2.0/schemas
+	doins "${FILESDIR}"/org.gnome.settings-daemon.plugins.power.gschema.override
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	udev_reload
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}