gui-wm/dwl: add missing RDEPEND on x11-base/xwayland

this has never been a problem because gui-libs/wlroots[X] also depends
on it, but add it for correctness

Signed-off-by: Leonardo Hernández Hernández <leohdz172@proton.me>
Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 102 insertions, 6 deletions

diff --git a/gui-wm/dwl/dwl-0.5-r1.ebuild b/gui-wm/dwl/dwl-0.5-r1.ebuild
new file mode 100644
index 000000000000..f94a2aa83609
--- /dev/null
+++ b/gui-wm/dwl/dwl-0.5-r1.ebuild
@@ -0,0 +1,86 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit savedconfig toolchain-funcs
+
+MY_P="${PN}-v${PV}"
+
+WLROOTS_DEP="
+	>=gui-libs/wlroots-0.17:=[libinput,session,X?]
+	<gui-libs/wlroots-0.18:=
+"
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://codeberg.org/dwl/dwl.git"
+	inherit git-r3
+
+	# 9999-r0: main (latest stable wlroots release)
+	# 9999-r1: wlroots-next (wlroots-9999)
+	case ${PVR} in
+		9999)
+			EGIT_BRANCH=main
+			;;
+		9999-r1)
+			EGIT_BRANCH=wlroots-next
+			WLROOTS_DEP="~gui-libs/wlroots-9999:=[libinput,session,X?]"
+			;;
+	esac
+else
+	SRC_URI="https://codeberg.org/${PN}/${PN}/releases/download/v${PV}/${MY_P}.tar.gz"
+	S="${WORKDIR}/${MY_P}"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+fi
+
+DESCRIPTION="dwm for Wayland"
+HOMEPAGE="https://codeberg.org/dwl/dwl"
+
+LICENSE="CC0-1.0 GPL-3+ MIT"
+SLOT="0"
+IUSE="X"
+
+CDEPEND="
+	${WLROOTS_DEP}
+	dev-libs/libinput:=
+	dev-libs/wayland
+	x11-libs/libxkbcommon
+	X? (
+		x11-libs/libxcb:=
+		x11-libs/xcb-util-wm
+	)
+"
+RDEPEND="
+	${CDEPEND}
+	X? (
+		x11-base/xwayland
+	)
+"
+# uses <linux/input-event-codes.h>
+DEPEND="
+	${CDEPEND}
+	sys-kernel/linux-headers
+"
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.32
+	dev-util/wayland-scanner
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	restore_config config.h
+
+	default
+}
+
+src_compile() {
+	emake PKG_CONFIG="$(tc-getPKG_CONFIG)" CC="$(tc-getCC)" \
+		XWAYLAND="$(usev X -DXWAYLAND)" XLIBS="$(usev X "xcb xcb-icccm")" dwl
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
+	dodoc CHANGELOG.md README.md
+
+	save_config config.h
+}
diff --git a/gui-wm/dwl/dwl-9999-r1.ebuild b/gui-wm/dwl/dwl-9999-r1.ebuild
index 64c73b5b8ef2..7a8722df0d60 100644
--- a/gui-wm/dwl/dwl-9999-r1.ebuild
+++ b/gui-wm/dwl/dwl-9999-r1.ebuild
@@ -40,7 +40,7 @@ LICENSE="CC0-1.0 GPL-3+ MIT"
 SLOT="0"
 IUSE="X"
 
-RDEPEND="
+CDEPEND="
 	${WLROOTS_DEP}
 	dev-libs/libinput:=
 	dev-libs/wayland
@@ -50,10 +50,15 @@ RDEPEND="
 		x11-libs/xcb-util-wm
 	)
 "
-
+RDEPEND="
+	${CDEPEND}
+	X? (
+		x11-base/xwayland
+	)
+"
 # uses <linux/input-event-codes.h>
 DEPEND="
-	${RDEPEND}
+	${CDEPEND}
 	sys-kernel/linux-headers
 "
 BDEPEND="
diff --git a/gui-wm/dwl/dwl-9999.ebuild b/gui-wm/dwl/dwl-9999.ebuild
index 11f48b8e090b..f94a2aa83609 100644
--- a/gui-wm/dwl/dwl-9999.ebuild
+++ b/gui-wm/dwl/dwl-9999.ebuild
@@ -40,7 +40,7 @@ LICENSE="CC0-1.0 GPL-3+ MIT"
 SLOT="0"
 IUSE="X"
 
-RDEPEND="
+CDEPEND="
 	${WLROOTS_DEP}
 	dev-libs/libinput:=
 	dev-libs/wayland
@@ -50,10 +50,15 @@ RDEPEND="
 		x11-libs/xcb-util-wm
 	)
 "
-
+RDEPEND="
+	${CDEPEND}
+	X? (
+		x11-base/xwayland
+	)
+"
 # uses <linux/input-event-codes.h>
 DEPEND="
-	${RDEPEND}
+	${CDEPEND}
 	sys-kernel/linux-headers
 "
 BDEPEND="