kde-apps/kig: 23.04.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/kde-apps/kig/Manifest b/kde-apps/kig/Manifest
index 00dd9fc90e8b..816e2db685ae 100644
--- a/kde-apps/kig/Manifest
+++ b/kde-apps/kig/Manifest
@@ -1 +1,2 @@
 DIST kig-22.12.3.tar.xz 3281480 BLAKE2B 7346f18eef68813a3f65e83981cf88a60129e7bf1b2ad9c9faf55a0eb96e187fd3bdbb731f221d2660349d7fe5e0df004c968fb57758ec831f6b9639f098d66e SHA512 c42d200899da04d1b6cdfd05d04b6b7e4dbee6d81dc7e92604642e0621a31fdd693bb6d26f0242c4fcaa994f9fe47dbb63d136aa06117f689f2ebb5bb2c77e78
+DIST kig-23.04.0.tar.xz 3281420 BLAKE2B 2d2858c8f49bc0d416bb2d90d187a40aedbbaae51ce9495362dd0e5a554f9a98651fdf5c02321ef3b2e3f00268d2b99b2dbd618cc6114fed15d6f9de805850c3 SHA512 0cf23194d1ef1b25b554a9cc3a635075cfd9a0b62e9a26a46e5c693166225573e3410861b56b23d9d2b59dc8bdce5d36c26a2373b9d12f534f78be0f5ef44b49
diff --git a/kde-apps/kig/kig-23.04.0.ebuild b/kde-apps/kig/kig-23.04.0.ebuild
new file mode 100644
index 000000000000..91481f374034
--- /dev/null
+++ b/kde-apps/kig/kig-23.04.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+PYTHON_COMPAT=( python3_{9..11} )
+KFMIN=5.104.0
+QTMIN=5.15.5
+inherit python-single-r1 ecm gear.kde.org
+
+DESCRIPTION="KDE Interactive Geometry tool"
+HOMEPAGE="https://apps.kde.org/kig/ https://edu.kde.org/kig/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="geogebra scripting"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	geogebra? ( >=dev-qt/qtxmlpatterns-${QTMIN}:5 )
+	scripting? (
+		$(python_gen_cond_dep '
+			>=dev-libs/boost-1.70:=[python,${PYTHON_USEDEP}]
+		')
+	)
+"
+DEPEND="${RDEPEND}
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-20.08.70-cmake-boostpython.patch )
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_prepare() {
+	ecm_src_prepare
+	python_fix_shebang .
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBOOSTPYTHON_VERSION_MAJOR_MINOR=${EPYTHON}
+		$(cmake_use_find_package geogebra Qt5XmlPatterns)
+		$(cmake_use_find_package scripting Boost)
+	)
+
+	ecm_src_configure
+}