kde-frameworks/kfilemetadata: 5.113.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 67 insertions, 0 deletions

diff --git a/kde-frameworks/kfilemetadata/Manifest b/kde-frameworks/kfilemetadata/Manifest
index decf66441ee9..1a6ebff616e7 100644
--- a/kde-frameworks/kfilemetadata/Manifest
+++ b/kde-frameworks/kfilemetadata/Manifest
@@ -1 +1,2 @@
 DIST kfilemetadata-5.112.0.tar.xz 472928 BLAKE2B 9f0867b95abe33c37227d0955fd7044548baf1d1b07ccc74950d15d65e3c61cda0bca44198e0a2b12e3e7d2f763db436a7612ab5f5b5ecc9f6093e2415a51a1a SHA512 6d7e6a25c9360edc274baa5de578afe088e2d4c5ef53f81329b806defbcb7dd7084975b2367972a5a5d8915c07cc2cecc243e0ad750e443801f8c11d693aa787
+DIST kfilemetadata-5.113.0.tar.xz 526884 BLAKE2B 3b4d1ad31f7ca8fb07ea0b41524d6280be1ba7954d4eeefcb9a41e945a37a6ccecde7d8eece38653548cb1dfd6b41ed8bfaa501ac0b4ca60b3439148e233878d SHA512 95790940e1d04849ed25046da38ccd62f6929108c205ec8bff3bbb912c03dd2e28ce2ecf5e544320aa73482a6ea5146d2bc71638e98b36b037f0d77ab3abc46d
diff --git a/kde-frameworks/kfilemetadata/kfilemetadata-5.113.0.ebuild b/kde-frameworks/kfilemetadata/kfilemetadata-5.113.0.ebuild
new file mode 100644
index 000000000000..d9c9d55c22c7
--- /dev/null
+++ b/kde-frameworks/kfilemetadata/kfilemetadata-5.113.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.9
+inherit ecm frameworks.kde.org optfeature python-any-r1
+
+DESCRIPTION="Library for extracting file metadata"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="epub exif ffmpeg mobi pdf taglib"
+
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	=kde-frameworks/karchive-${PVCUT}*:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	=kde-frameworks/ki18n-${PVCUT}*:5
+	epub? ( app-text/ebook-tools )
+	exif? ( media-gfx/exiv2:= )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	mobi? ( kde-apps/kdegraphics-mobipocket:5 )
+	pdf? ( app-text/poppler[qt5] )
+	taglib? ( media-libs/taglib )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-apps/attr )
+"
+BDEPEND="test? ( ${PYTHON_DEPS} )"
+
+CMAKE_SKIP_TESTS=(
+	# FIXME: bug 644650, fails on tmpfs (but not for everyone)
+	usermetadatawritertest
+)
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package epub EPub)
+		$(cmake_use_find_package exif LibExiv2)
+		$(cmake_use_find_package ffmpeg FFmpeg)
+		$(cmake_use_find_package mobi QMobipocket)
+		$(cmake_use_find_package pdf Poppler)
+		$(cmake_use_find_package taglib Taglib)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "Microsoft Word/Powerpoint file indexing" app-text/catdoc
+		optfeature "Microsoft Excel file indexing" dev-libs/libxls
+	fi
+	ecm_pkg_postinst
+}