kde-plasma/plasma-desktop: 5.22.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 185 insertions, 0 deletions

diff --git a/kde-plasma/plasma-desktop/Manifest b/kde-plasma/plasma-desktop/Manifest
index 880422841a7b..200aa2eb29a4 100644
--- a/kde-plasma/plasma-desktop/Manifest
+++ b/kde-plasma/plasma-desktop/Manifest
@@ -1,4 +1,5 @@
 DIST plasma-desktop-5.21.5.tar.xz 15913496 BLAKE2B 6923a4c48d20f2611ab92ec34517a339a4fbc53875545beb5c33700933262f67b48b22ea311812d7b0cd4a169a4b19f497c0cd559c5b5f74e52410e30c187ec7 SHA512 40814910676a05d3d5a308a432c06ce9664b90724fe8c56c4f68f6eb939f35401f19dddb8c46006f44fa418e0f18b4a42b0ff78b5b07031f54e6b3c10c919e57
 DIST plasma-desktop-5.22.1.tar.xz 15736412 BLAKE2B c6a74b1f9b1212fb82c6903c4056a0545fade1400744bd9cf67cfbf36995699ffcc7fdd62e99adbe58753a536b89b83069d76766d403da1d1760c59527746fdb SHA512 161e0b39bbe01a06e250e252a52cbe3188b1dc87c21c60dd61eab179d63bfbb60c905bf58706efe2bdb39c52c5b673845064f581ca14ceac7b64191ab365e6d0
+DIST plasma-desktop-5.22.2.tar.xz 15736384 BLAKE2B e255a7fc0eee3efcd36eedc3ea7c1e71f3938c68a2ff6c81e0f4ddc73100a31ec5bc999a3eaddfc63d3bbdfef9120a0f3751fea11ae25e849df6734de6c0704f SHA512 25b37aaeceaf39f1b12adee3c4e451a38c1181c98e10af477655857d2268b7a6ff34ec21a2612e35d97529b831d969d0bf94f442bf3bd49b232d86cecc32380a
 DIST plasma-desktop-override-include-dirs-0.tar.xz 7504 BLAKE2B 781a2f0f7ca5a45b966edfc79012e80c6826262a211d95b725590191a8828e0002fd924a49cc63c12090535077a24f3e719ca3277aac89aba3092e86f73d7f61 SHA512 d23dc203b8b645472c9c192a3d73ef9b46c66d9c64df1c90efa05c9968ec125e0a256bc9b654f05a1f22bce4b1d8aad436f581b42d579f4195a44f062fd444bb
 DIST plasma-desktop-override-include-dirs-1.tar.xz 7888 BLAKE2B f1e416fa0ed27cfe6e049cafc66d1603bb4f76f0cec16dc47339a238cbb485b202adf08ececbb8933a5e1a54954cbd21653d2c9dfec27baa49fdf583acf0d75f SHA512 aa26b4966a5d00c378128ee8ee56025d637f139fcd315bf0aabefa080caecadf8cd3176dee3df87d4f8bdc48446df535260cf64a65055857fb895fa8988e1a20
diff --git a/kde-plasma/plasma-desktop/plasma-desktop-5.22.2.ebuild b/kde-plasma/plasma-desktop/plasma-desktop-5.22.2.ebuild
new file mode 100644
index 000000000000..e3ac5f790ba3
--- /dev/null
+++ b/kde-plasma/plasma-desktop/plasma-desktop-5.22.2.ebuild
@@ -0,0 +1,184 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+KFMIN=5.82.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org optfeature
+
+DESCRIPTION="KDE Plasma desktop"
+XORGHDRS="${PN}-override-include-dirs-1"
+SRC_URI+=" https://dev.gentoo.org/~asturm/distfiles/${XORGHDRS}.tar.xz"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="emoji ibus +kaccounts +policykit scim +semantic-desktop"
+
+COMMON_DEPEND="
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/attica-${KFMIN}:5
+	>=kde-frameworks/kactivities-${KFMIN}:5
+	>=kde-frameworks/kactivities-stats-${KFMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kded-${KFMIN}:5
+	>=kde-frameworks/kdelibs4support-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/krunner-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=kde-frameworks/sonnet-${KFMIN}:5
+	>=kde-plasma/kwin-${PVCUT}:5
+	>=kde-plasma/libksysguard-${PVCUT}:5
+	>=kde-plasma/libkworkspace-${PVCUT}:5
+	>=kde-plasma/plasma-workspace-${PVCUT}:5
+	>=media-libs/phonon-4.11.0
+	virtual/libcrypt:=
+	x11-libs/libX11
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libxcb[xkb]
+	x11-libs/libxkbfile
+	emoji? (
+		app-i18n/ibus[emoji]
+		dev-libs/glib:2
+		media-fonts/noto-emoji
+	)
+	ibus? (
+		app-i18n/ibus
+		dev-libs/glib:2
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libxcb
+		x11-libs/xcb-util-keysyms
+	)
+	kaccounts? (
+		kde-apps/kaccounts-integration:5
+		net-libs/accounts-qt
+	)
+	policykit? ( >=kde-frameworks/kwallet-${KFMIN}:5 )
+	scim? ( app-i18n/scim )
+	semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/boost
+	x11-base/xorg-proto
+"
+RDEPEND="${COMMON_DEPEND}
+	!kde-plasma/user-manager
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/qqc2-desktop-style-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+	>=kde-plasma/oxygen-${PVCUT}:5
+	sys-apps/util-linux
+	x11-apps/setxkbmap
+	x11-misc/xdg-user-dirs
+	kaccounts? ( net-libs/signon-oauth2 )
+	policykit? ( sys-apps/accountsservice )
+"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${WORKDIR}/${XORGHDRS}/override-include-dirs.patch" # downstream patch
+)
+
+src_prepare() {
+	ecm_src_prepare
+
+	if ! use policykit; then
+		ecm_punt_bogus_dep KF5 Wallet
+		cmake_run_in kcms cmake_comment_add_subdirectory users
+	fi
+
+	if ! use ibus; then
+		sed -e "s/Qt5X11Extras_FOUND AND XCB_XCB_FOUND AND XCB_KEYSYMS_FOUND/false/" \
+			-i applets/kimpanel/backend/ibus/CMakeLists.txt || die
+	fi
+
+	use emoji || cmake_run_in applets/kimpanel/backend/ibus \
+		cmake_comment_add_subdirectory emojier
+
+	# TODO: try to get a build switch upstreamed
+	if ! use scim; then
+		sed -e "s/^pkg_check_modules.*SCIM/#&/" -i CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_PackageKitQt5=ON # not packaged
+		-DEVDEV_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+		-DXORGLIBINPUT_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+		-DXORGSERVER_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+		-DSYNAPTICS_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+		$(cmake_use_find_package kaccounts AccountsQt5)
+		$(cmake_use_find_package kaccounts KAccounts)
+		$(cmake_use_find_package semantic-desktop KF5Baloo)
+	)
+	if ! use emoji && ! use ibus; then
+		mycmakeargs+=( -DCMAKE_DISABLE_FIND_PACKAGE_GLIB2=ON )
+	fi
+
+	ecm_src_configure
+}
+
+src_test() {
+	# parallel tests fail, foldermodeltest,positionertest hang, bug #646890
+	# test_kio_fonts needs D-Bus, bug #634166
+	# lookandfeel-kcmTest is unreliable for a long time, bug #607918
+	local myctestargs=(
+		-j1
+		-E "(foldermodeltest|positionertest|test_kio_fonts|lookandfeel-kcmTest)"
+	)
+
+	ecm_src_test
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "screen reader support" app-accessibility/orca
+	fi
+	ecm_pkg_postinst
+}