kde-plasma/plasma-desktop: 5.24.5 version bump

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 179 insertions, 0 deletions

diff --git a/kde-plasma/plasma-desktop/Manifest b/kde-plasma/plasma-desktop/Manifest
index c8559e189b34..f698af5676f4 100644
--- a/kde-plasma/plasma-desktop/Manifest
+++ b/kde-plasma/plasma-desktop/Manifest
@@ -1,3 +1,4 @@
 DIST plasma-desktop-5.23.5.tar.xz 15794548 BLAKE2B 6e215cc5ef10598308a9fbe6c58ea67ea16ee3c3394c69bebcd1167b939e8ff1442bc839c87428cc5a57b274cc95d02983a67ab0e8fac6c27435e446f84c8630 SHA512 14cd20b24e265ef9cc4e4ebbfc743151cf5f9ba0a94fbc19e44571c7e68db61d68bab17dd1feea6f4e0844ab448110010fbfe85212b426c1e12232b73bd1c531
 DIST plasma-desktop-5.24.4.tar.xz 6239980 BLAKE2B 0b8af5d596e277d202a9c088aa561ce3f0c3602ca781c807b4082f37da4269176429946edf0665ebd9bc6046cd6b0a97baf5a67ec3c0194c23d6fe237a56c18d SHA512 9d6a8c50a85d7f59b89a13753d9a7072df5e8bd1e726bf1037c4cf8d4d43046c2076c8993dffc1f5cec7f7a113832dd14f836e9b47b879f6352f3c30f4b5c408
+DIST plasma-desktop-5.24.5.tar.xz 6241532 BLAKE2B 20bec56fbd0c3f68b3eaf75cb18a01888c63a8d49e2761c83858125ef82dfe225137e9ba704eaddc43405fe6f9818f879f0105eff03d06aa74d93800e4891693 SHA512 3bb770023b47dcc3c51dbdacfe9cb93adc2f514d8d19f54fed10023d9440bed956ec3beb18d9979cb408ab2e6e960ca383d215fd072ba2df34e4e0b5f6c55270
 DIST plasma-desktop-override-include-dirs-1.tar.xz 7888 BLAKE2B f1e416fa0ed27cfe6e049cafc66d1603bb4f76f0cec16dc47339a238cbb485b202adf08ececbb8933a5e1a54954cbd21653d2c9dfec27baa49fdf583acf0d75f SHA512 aa26b4966a5d00c378128ee8ee56025d637f139fcd315bf0aabefa080caecadf8cd3176dee3df87d4f8bdc48446df535260cf64a65055857fb895fa8988e1a20
diff --git a/kde-plasma/plasma-desktop/plasma-desktop-5.24.5.ebuild b/kde-plasma/plasma-desktop/plasma-desktop-5.24.5.ebuild
new file mode 100644
index 000000000000..302d9b8d656b
--- /dev/null
+++ b/kde-plasma/plasma-desktop/plasma-desktop-5.24.5.ebuild
@@ -0,0 +1,178 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+KFMIN=5.90.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org optfeature
+
+DESCRIPTION="KDE Plasma desktop"
+XORGHDRS="${PN}-override-include-dirs-1"
+SRC_URI+=" https://dev.gentoo.org/~asturm/distfiles/${XORGHDRS}.tar.xz"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="emoji ibus +kaccounts scim +semantic-desktop telemetry"
+
+COMMON_DEPEND="
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/attica-${KFMIN}:5
+	>=kde-frameworks/kactivities-${KFMIN}:5
+	>=kde-frameworks/kactivities-stats-${KFMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kded-${KFMIN}:5
+	>=kde-frameworks/kdelibs4support-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/krunner-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=kde-frameworks/sonnet-${KFMIN}:5
+	>=kde-plasma/kwin-${PVCUT}:5
+	>=kde-plasma/libksysguard-${PVCUT}:5
+	>=kde-plasma/libkworkspace-${PVCUT}:5
+	>=kde-plasma/plasma-workspace-${PVCUT}:5
+	>=media-libs/phonon-4.11.0
+	x11-libs/libX11
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libxcb[xkb]
+	x11-libs/libxkbfile
+	emoji? (
+		app-i18n/ibus[emoji]
+		dev-libs/glib:2
+		media-fonts/noto-emoji
+	)
+	ibus? (
+		app-i18n/ibus
+		dev-libs/glib:2
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libxcb
+		x11-libs/xcb-util-keysyms
+	)
+	kaccounts? (
+		kde-apps/kaccounts-integration:5
+		net-libs/accounts-qt
+	)
+	scim? ( app-i18n/scim )
+	semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
+	telemetry? ( dev-libs/kuserfeedback:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/boost
+	x11-base/xorg-proto
+"
+RDEPEND="${COMMON_DEPEND}
+	!kde-plasma/user-manager
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/qqc2-desktop-style-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+	>=kde-plasma/oxygen-${PVCUT}:5
+	sys-apps/util-linux
+	x11-apps/setxkbmap
+	x11-misc/xdg-user-dirs
+	kaccounts? ( net-libs/signon-oauth2 )
+"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${WORKDIR}/${XORGHDRS}/override-include-dirs.patch" # downstream patch
+)
+
+src_prepare() {
+	ecm_src_prepare
+
+	if ! use ibus; then
+		sed -e "s/Qt5X11Extras_FOUND AND XCB_XCB_FOUND AND XCB_KEYSYMS_FOUND/false/" \
+			-i applets/kimpanel/backend/ibus/CMakeLists.txt || die
+	fi
+
+	use emoji || cmake_run_in applets/kimpanel/backend/ibus \
+		cmake_comment_add_subdirectory emojier
+
+	# TODO: try to get a build switch upstreamed
+	if ! use scim; then
+		sed -e "s/^pkg_check_modules.*SCIM/#&/" -i CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_PackageKitQt5=ON # not packaged
+		-DEVDEV_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+		-DXORGLIBINPUT_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+		-DXORGSERVER_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+		-DSYNAPTICS_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+		$(cmake_use_find_package kaccounts AccountsQt5)
+		$(cmake_use_find_package kaccounts KAccounts)
+		$(cmake_use_find_package semantic-desktop KF5Baloo)
+		$(cmake_use_find_package telemetry KUserFeedback)
+	)
+	if ! use emoji && ! use ibus; then
+		mycmakeargs+=( -DCMAKE_DISABLE_FIND_PACKAGE_GLIB2=ON )
+	fi
+
+	ecm_src_configure
+}
+
+src_test() {
+	# parallel tests fail, foldermodeltest,positionertest hang, bug #646890
+	# test_kio_fonts needs D-Bus, bug #634166
+	# lookandfeel-kcmTest is unreliable for a long time, bug #607918
+	local myctestargs=(
+		-j1
+		-E "(foldermodeltest|positionertest|test_kio_fonts|lookandfeel-kcmTest)"
+	)
+
+	ecm_src_test
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "screen reader support" app-accessibility/orca
+	fi
+	ecm_pkg_postinst
+}