media-gfx/imv: 4.2.0 bump

Is now using meson, and notably adds heif support.

Changes from previous live ebuild:
 - fix man pages missing when USE=-test
 - Allow direct backends even if freeimage is enabled
  (upstream sets freeimage as a fallback, so let it be so)
 - new inih dep (#760471)
 - force removal of unused virtual/glu dep
 - reviewed and updated all other deps (e.g. SDL unused)
 - allow building X11-less with libglvnd[-X]
  (but now use X by default to satisfy required use)
 - various cleanups

Patches:
 - fix segmentation fault when imv[freeimage,-svg]
 - fix flickering issue on wayland (upstream backport)

Closes: https://bugs.gentoo.org/760471
Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: Ionen Wolkens <sudinave@gmail.com>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 46 insertions, 54 deletions

diff --git a/media-gfx/imv/imv-9999.ebuild b/media-gfx/imv/imv-9999.ebuild
index 65f50d9221c2..7ea6a9466428 100644
--- a/media-gfx/imv/imv-9999.ebuild
+++ b/media-gfx/imv/imv-9999.ebuild
@@ -1,89 +1,81 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
-inherit git-r3 meson xdg-utils
+inherit xdg meson
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/eXeC64/imv.git"
+else
+	SRC_URI="https://github.com/eXeC64/imv/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
 
 DESCRIPTION="Minimal image viewer designed for tiling window manager users"
-LICENSE="MIT-with-advertising"
 HOMEPAGE="https://github.com/eXeC64/imv"
-EGIT_REPO_URI="https://github.com/eXeC64/imv"
 
-KEYWORDS=""
+LICENSE="MIT-with-advertising"
 SLOT="0"
-IUSE="X +freeimage +png jpeg svg gif heif test tiff wayland"
+IUSE="+X +freeimage gif heif jpeg png svg test tiff wayland"
+REQUIRED_USE="|| ( X wayland )"
 RESTRICT="!test? ( test )"
-REQUIRED_USE="
-	|| ( X wayland )
-"
 
 RDEPEND="
-	!sys-apps/renameutils
 	dev-libs/icu:=
-	media-libs/fontconfig
-	media-libs/libsdl2
-	media-libs/sdl2-ttf
+	dev-libs/inih
+	media-libs/libglvnd[X?]
+	x11-libs/libxkbcommon[X?]
+	x11-libs/pango
 	X? (
-		virtual/glu
 		x11-libs/libX11
-		x11-libs/libxcb
-		x11-libs/libxkbcommon[X]
-		x11-libs/pango
-	)
-	freeimage? ( media-libs/freeimage[png?,jpeg?,tiff?] )
-	!freeimage? (
-		jpeg? ( media-libs/libjpeg-turbo )
-		png? ( media-libs/libpng )
-		tiff? ( media-libs/tiff )
+		x11-libs/libxcb:=
 	)
+	freeimage? ( media-libs/freeimage )
 	gif? ( media-libs/libnsgif )
-	heif? ( media-libs/libheif )
+	heif? ( media-libs/libheif:= )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	png? ( media-libs/libpng:= )
 	svg? ( >=gnome-base/librsvg-2.44 )
+	tiff? ( media-libs/tiff )
 	wayland? ( dev-libs/wayland )
-"
-BDEPEND="
-	app-text/asciidoc
-	test? ( dev-util/cmocka )
+	!sys-apps/renameutils
 "
 DEPEND="
 	${RDEPEND}
+	test? ( dev-util/cmocka )
+"
+BDEPEND="
+	app-text/asciidoc
 "
 
-src_configure() {
-	local WINDOWS
-	if use X; then
-		if ! use wayland; then
-			WINDOWS=x11
-		else
-			WINDOWS=all
-		fi
-	else
-		if use wayland; then
-			WINDOWS=wayland
-		fi
-	fi
+src_prepare() {
+	default
 
-	if ! use test; then
-		sed -i -e '/^dep_cmocka/,/^endforeach$/d' meson.build || die
+	# allow building with libglvnd[-X]
+	if ! use X; then
+		sed -i "/dependency('gl')/s/gl/opengl/" meson.build || die
 	fi
 
+	# glu isn't used by anything
+	sed -i "/dependency('glu')/d" meson.build || die
+}
+
+src_configure() {
+	local WINDOWS=all
+	use X || WINDOWS=wayland
+	use wayland || WINDOWS=x11
+
 	local emesonargs=(
 		$(meson_feature freeimage)
 		$(meson_feature gif libnsgif)
 		$(meson_feature heif libheif)
+		$(meson_feature jpeg libjpeg)
+		$(meson_feature png libpng)
 		$(meson_feature svg librsvg)
-		$(usex freeimage -Dlibjpeg=disabled -Dlibjpeg=enabled)
-		$(usex freeimage -Dlibpng=disabled -Dlibjpeg=enabled)
-		$(usex freeimage -Dlibtiff=disabled -Dlibjpeg=enabled)
+		$(meson_feature test)
+		$(meson_feature tiff libtiff)
 		-Dwindows=$WINDOWS
 	)
 	meson_src_configure
 }
-
-pkg_postinst() {
-	xdg_desktop_database_update
-}
-
-pkg_postrm() {
-	xdg_desktop_database_update
-}